reserve T for non empty TopSpace,
  A, B for Subset of T,
  F, G for Subset-Family of T;

theorem
  for A being Subset of R^1 st A = RAT holds A is F_sigma
proof
  defpred R[object] means ex a being Element of RAT st a = $1;
  defpred P[object] means ex a being Element of RAT st {a} = $1;
  let A be Subset of R^1;
  ex F being set st for x being set holds x in F iff x in bool RAT & P[x]
  from XFAMILY:sch 1;
  then consider F being set such that
A1: for x being set holds x in F iff x in bool RAT & P[x];
A2: bool RAT c= bool REAL by NUMBERS:12,ZFMISC_1:67;
  F c= bool the carrier of R^1
  by A1,A2,TOPMETR:17;
  then reconsider F as Subset-Family of R^1;
  assume
A3: A = RAT;
  ex F being Subset-Family of R^1 st F is closed countable & A = union F
  proof
    take F;
    for B being Subset of R^1 st B in F holds B is closed
    proof
      let B be Subset of R^1;
      assume B in F;
      then ex a being Element of RAT st {a} = B by A1;
      hence thesis;
    end;
    hence F is closed by TOPS_2:def 2;
A4: F = { {x} where x is Element of RAT : R[x] }
    proof
      thus F c= { {x} where x is Element of RAT : R[x] }
      proof
        let y be object;
        assume y in F;
        then P[y] by A1;
        hence thesis;
      end;
      let y be object;
      assume y in { {x} where x is Element of RAT : R[x] };
      then ex z being Element of RAT st y = {z} & R[z];
      hence thesis by A1;
    end;
    { {x} where x is Element of RAT : R[x] } is countable from
    FraenCoun11;
    hence F is countable by A4;
    thus A c= union F
    proof
      let x be object;
      assume x in A;
      then reconsider x as Element of RAT by A3;
      {x} in F & x in {x} by A1,TARSKI:def 1;
      hence thesis by TARSKI:def 4;
    end;
    let x be object;
    assume x in union F;
    then consider Y being set such that
A5: x in Y and
A6: Y in F by TARSKI:def 4;
    ex a being Element of RAT st {a} = Y by A1,A6;
    hence thesis by A3,A5;
  end;
  hence thesis;
end;
