reserve
  S for (4,1) integer bool-correct non empty non void BoolSignature,
  X for non-empty ManySortedSet of the carrier of S,
  T for vf-free integer all_vars_including inheriting_operations free_in_itself
  (X,S)-terms VarMSAlgebra over S,
  C for (4,1) integer bool-correct non-empty image of T,
  G for basic GeneratorSystem over S,X,T,
  A for IfWhileAlgebra of the generators of G,
  I for integer SortSymbol of S,
  x,y,z,m for pure (Element of (the generators of G).I),
  b for pure (Element of (the generators of G).the bool-sort of S),
  t,t1,t2 for Element of T,I,
  P for Algorithm of A,
  s,s1,s2 for Element of C-States(the generators of G);
reserve
  f for ExecutionFunction of A, C-States(the generators of G),
  (\falseC)-States(the generators of G, b);
reserve u for ManySortedFunction of FreeGen T, the Sorts of C;

theorem Th46:
  \trueT value_at(C,u) = TRUE
  proof
    consider f being ManySortedFunction of T,C such that
A1: f is_homomorphism T,C & u = f||FreeGen T by MSAFREE4:46;
    FreeGen T is_transformable_to the Sorts of C
    by MSAFREE4:21;
    then
    doms u = FreeGen T by MSSUBFAM:17;
    then consider f being ManySortedFunction of T,C,
    Q being GeneratorSet of T such that
A2: f is_homomorphism T,C & Q = doms u & u = f||Q &
    \trueT value_at(C,u) = f.(the bool-sort of S).\trueT by A1,AOFA_A00:def 21;
    set o = In((the connectives of S).1, the carrier' of S);
A3: o = (the connectives of S).1 &
    the_arity_of o = {} & the_result_sort_of o = the bool-sort of S by Th11;
    then
    Args(o,T) = {{}} by Th21;
    then reconsider p = {} as Element of Args(o,T) by TARSKI:def 1;
    dom(f#p) = {} & dom p = {} by A3,MSUALG_3:6;
    then
A4: p = f#p;
    f.(the bool-sort of S).\trueT = \trueC by A4,A2,A3
    .= TRUE by AOFA_A00:def 32;
    hence thesis by A2;
  end;
