reserve            x for object,
               X,Y,Z for set,
         i,j,k,l,m,n for Nat,
                 r,s for Real,
                  no for Element of OrderedNAT,
                   A for Subset of [:NAT,NAT:];
reserve X,Y,X1,X2 for non empty set,
          cA1,cB1 for filter_base of X1,
          cA2,cB2 for filter_base of X2,
              cF1 for Filter of X1,
              cF2 for Filter of X2,
             cBa1 for basis of cF1,
             cBa2 for basis of cF2;

theorem Th38:
  ([:NAT,NAT:] \ the set of all [0,n] where n is Nat)
    in <. Frechet_Filter(NAT),Frechet_Filter(NAT).) &
  not ([:NAT,NAT:] \ the set of all [0,n] where n is Nat)
    in Frechet_Filter([:NAT,NAT:])
  proof
    set X = [:NAT,NAT:] \ the set of all [0,n] where n is Nat;
A1: square-uparrow 1 c= X
    proof
      let x be object;
      assume x in square-uparrow 1;
      then x in [:NAT \ Segm 1,NAT \ Segm 1:] by Th27;
      then consider n,m be object such that
A2:   n in NAT \ Segm 1 and
A3:   m in NAT \ Segm 1 and
A4:   x = [n,m] by ZFMISC_1:def 2;
      reconsider n,m as Nat by A2,A3;
A5:   x in [:NAT,NAT:] by A4,A2,A3,ZFMISC_1:def 2;
      not n in Segm 1 by A2,XBOOLE_0:def 5;
      then
A6:   not n = 0 by NAT_1:44;
      not x in (the set of all [0,n] where n is Nat)
      proof
        assume not thesis;
        then ex k be Nat st x = [0,k];
        hence thesis by A6,A4,XTUPLE_0:1;
      end;
      hence thesis by A5,XBOOLE_0:def 5;
    end;
    square-uparrow 1 in the set of all square-uparrow n where n is Nat;
    hence X in <. Frechet_Filter(NAT),Frechet_Filter(NAT).)
      by A1,CARDFIL2:def 8,Th36;
    thus not X in Frechet_Filter([:NAT,NAT:])
    proof
      assume not thesis;
      then X in the set of all [:NAT,NAT:] \ A where
        A is finite Subset of [:NAT,NAT:] by CARDFIL2:51;
      then consider A be finite Subset of [:NAT,NAT:] such that
A7:   X = [:NAT,NAT:] \ A;
      the set of all [0,n] where n is Nat c= [:NAT,NAT:]
      proof
        let x be object;
        assume x in the set of all [0,n] where n is Nat;
        then consider n be Nat such that
A8:     x = [0,n];
        n in NAT & 0 in NAT by ORDINAL1:def 12;
        hence thesis by A8,ZFMISC_1:def 2;
      end;
      hence contradiction by A7,COMBGRAS:5,Th9;
    end;
  end;
