reserve a for Real;
reserve p,q for Point of TOP-REAL 2;

theorem
  for sn being Real,q1,q2 being Point of TOP-REAL 2 st -1<sn & sn<1 & q1
  `1 < 0 & q2`1<0 & q1`2/|.q1.|<q2`2/|.q2.| holds for p1,p2 being Point of
TOP-REAL 2 st p1=(sn-FanMorphW).q1 & p2=(sn-FanMorphW).q2 holds p1`2/|.p1.|<p2
  `2/|.p2.|
proof
  let sn be Real,q1,q2 be Point of TOP-REAL 2;
  assume that
A1: -1<sn and
A2: sn<1 and
A3: q1`1<0 and
A4: q2`1<0 and
A5: q1`2/|.q1.|<q2`2/|.q2.|;
  let p1,p2 be Point of TOP-REAL 2;
  assume that
A6: p1=(sn-FanMorphW).q1 and
A7: p2=(sn-FanMorphW).q2;
  now
    per cases;
    case
      q1`2/|.q1.|>=sn & q2`2/|.q2.|>=sn;
      hence thesis by A2,A3,A4,A5,A6,A7,Th44;
    end;
    case
      q1`2/|.q1.|>=sn & q2`2/|.q2.|<sn;
      hence thesis by A5,XXREAL_0:2;
    end;
    case
A8:   q1`2/|.q1.|<sn & q2`2/|.q2.|>=sn;
      then p2`2>=0 by A2,A4,A7,Th42;
      then
A9:   p2`2/|.p2.|>=0;
      p1`2<0 by A1,A3,A6,A8,Th43;
      hence thesis by A9,Lm1,JGRAPH_2:3,XREAL_1:141;
    end;
    case
      q1`2/|.q1.|<sn & q2`2/|.q2.|<sn;
      hence thesis by A1,A3,A4,A5,A6,A7,Th45;
    end;
  end;
  hence thesis;
end;
