reserve n for Nat;

theorem Th46:
  for C be Simple_closed_curve for i1,i2,j,k be Nat st
1 < i2 & i2 <= i1 & i1 < len Gauge(C,n) & 1 <= j & j <= k & k <= width Gauge(C,
n) & (LSeg(Gauge(C,n)*(i1,j),Gauge(C,n)*(i1,k)) \/ LSeg(Gauge(C,n)*(i1,k),Gauge
(C,n)*(i2,k))) /\ L~Upper_Seq(C,n) = {Gauge(C,n)*(i2,k)} & (LSeg(Gauge(C,n)*(i1
  ,j),Gauge(C,n)*(i1,k)) \/ LSeg(Gauge(C,n)*(i1,k),Gauge(C,n)*(i2,k))) /\ L~
Lower_Seq(C,n) = {Gauge(C,n)*(i1,j)} holds (LSeg(Gauge(C,n)*(i1,j),Gauge(C,n)*(
  i1,k)) \/ LSeg(Gauge(C,n)*(i1,k),Gauge(C,n)*(i2,k))) meets Upper_Arc C
proof
  let C be Simple_closed_curve;
  let i1,i2,j,k be Nat;
  set G = Gauge(C,n);
  set pio = LSeg(G*(i1,j),G*(i1,k));
  set poz = LSeg(G*(i1,k),G*(i2,k));
  set US = Upper_Seq(C,n);
  set LS = Lower_Seq(C,n);
  assume that
A1: 1 < i2 and
A2: i2 <= i1 and
A3: i1 < len G and
A4: 1 <= j and
A5: j <= k and
A6: k <= width G and
A7: (pio \/ poz) /\ L~US = {G*(i2,k)} and
A8: (pio \/ poz) /\ L~LS = {G*(i1,j)} and
A9: (pio \/ poz) misses Upper_Arc C;
  set Gi1k = G*(i1,k);
  set Gik = G*(i2,k);
A10: 1 <= k by A4,A5,XXREAL_0:2;
A11: i2 < len G by A2,A3,XXREAL_0:2;
  then
A12: [i2,k] in Indices G by A1,A6,A10,MATRIX_0:30;
  set Wmin = W-min L~Cage(C,n);
  set Wbo = W-bound L~Cage(C,n);
A13: len G = width G by JORDAN8:def 1;
  set go = R_Cut(US,Gik);
A14: len US >= 3 by JORDAN1E:15;
  then len US >= 1 by XXREAL_0:2;
  then 1 in dom US by FINSEQ_3:25;
  then
A15: US.1 = US/.1 by PARTFUN1:def 6
    .= Wmin by JORDAN1F:5;
  set Gij = G*(i1,j);
  set co = L_Cut(LS,Gij);
  Gij in {Gij} by TARSKI:def 1;
  then
A16: Gij in L~LS by A8,XBOOLE_0:def 4;
A17: 1 < i1 by A1,A2,XXREAL_0:2;
  then
A18: Gi1k`2 = G*(1,k)`2 by A3,A6,A10,GOBOARD5:1
    .= Gik`2 by A1,A6,A11,A10,GOBOARD5:1;
A19: j <= width G by A5,A6,XXREAL_0:2;
  then
A20: [i1,j] in Indices G by A3,A4,A17,MATRIX_0:30;
  len G >= 4 by JORDAN8:10;
  then
A21: len G >= 1 by XXREAL_0:2;
  then
A22: [len G,j] in Indices G by A4,A19,MATRIX_0:30;
A23: [1,k] in Indices G by A6,A10,A21,MATRIX_0:30;
A24: now
    assume Gik`1 = Wbo;
    then G*(1,k)`1 = G*(i2,k)`1 by A6,A10,A13,JORDAN1A:73;
    hence contradiction by A1,A12,A23,JORDAN1G:7;
  end;
A25: [i1,j] in Indices G by A3,A4,A17,A19,MATRIX_0:30;
  set pion = <*Gik,Gi1k,Gij*>;
A26: Gi1k in poz by RLTOPSP1:68;
  set UA = Upper_Arc C;
A27: Gi1k in pio by RLTOPSP1:68;
A28: [i1,k] in Indices G by A3,A6,A17,A10,MATRIX_0:30;
A29: now
    let n be Nat;
    assume n in dom pion;
    then n in {1,2,3} by FINSEQ_1:89,FINSEQ_3:1;
    then n = 1 or n = 2 or n = 3 by ENUMSET1:def 1;
    hence
    ex i,j be Nat st [i,j] in Indices G & pion/.n = G*(i,j) by A25
,A12,A28,FINSEQ_4:18;
  end;
  Gik in {Gik} by TARSKI:def 1;
  then
A30: Gik in L~US by A7,XBOOLE_0:def 4;
  set Emax = E-max L~Cage(C,n);
A31: len LS >= 1+2 by JORDAN1E:15;
  then
A32: len LS >= 1 by XXREAL_0:2;
  then
A33: 1 in dom LS by FINSEQ_3:25;
  then
A34: LS.1 = LS/.1 by PARTFUN1:def 6
    .= Emax by JORDAN1F:6;
  len LS in dom LS by A32,FINSEQ_3:25;
  then
A35: LS.len LS = LS/.len LS by PARTFUN1:def 6
    .= Wmin by JORDAN1F:8;
  set Ebo = E-bound L~Cage(C,n);
A36: L~<*Gik,Gi1k,Gij*> = poz \/ pio by TOPREAL3:16;
  Wmin`1 = Wbo by EUCLID:52
    .= G*(1,k)`1 by A6,A10,A13,JORDAN1A:73;
  then
A37: Gik <> US.1 by A1,A12,A15,A23,JORDAN1G:7;
  then reconsider go as being_S-Seq FinSequence of TOP-REAL 2 by A30,JORDAN3:35
;
A38: Gik in rng US by A1,A6,A11,A30,A10,JORDAN1G:4,JORDAN1J:40;
  then
A39: go is_sequence_on G by JORDAN1G:4,JORDAN1J:38;
  Gi1k`1 = G*(i1,1)`1 by A3,A6,A17,A10,GOBOARD5:2
    .= Gij`1 by A3,A4,A17,A19,GOBOARD5:2;
  then
A40: Gi1k = |[Gij`1,Gik`2]| by A18,EUCLID:53;
A41: [len G,k] in Indices G by A6,A10,A21,MATRIX_0:30;
A42: len go >= 1+1 by TOPREAL1:def 8;
  Wmin`1 = Wbo by EUCLID:52
    .= G*(1,k)`1 by A6,A10,A13,JORDAN1A:73;
  then
A43: Gij <> LS.len LS by A1,A2,A23,A35,A20,JORDAN1G:7;
  then reconsider co as being_S-Seq FinSequence of TOP-REAL 2 by A16,JORDAN3:34
;
A44: Gij in rng LS by A3,A4,A17,A16,A19,JORDAN1G:5,JORDAN1J:40;
  then
A45: co is_sequence_on G by JORDAN1G:5,JORDAN1J:39;
  Emax`1 = Ebo by EUCLID:52
    .= G*(len G,k)`1 by A6,A10,A13,JORDAN1A:71;
  then
A46: Gij <> LS.1 by A3,A20,A41,A34,JORDAN1G:7;
A47: len co >= 1+1 by TOPREAL1:def 8;
  then reconsider
  co as non constant s.c.c. being_S-Seq FinSequence of TOP-REAL 2
  by A45,JGRAPH_1:12,JORDAN8:5;
A48: L~co c= L~LS by A16,JORDAN3:42;
  len co >= 1 by A47,XXREAL_0:2;
  then 1 in dom co by FINSEQ_3:25;
  then
A49: co/.1 = co.1 by PARTFUN1:def 6
    .= Gij by A16,JORDAN3:23;
  then
A50: LSeg(co,1) = LSeg(Gij,co/.(1+1)) by A47,TOPREAL1:def 3;
A51: {Gij} c= LSeg(co,1) /\ L~<*Gik,Gi1k,Gij*>
  proof
    let x be object;
    assume x in {Gij};
    then
A52: x = Gij by TARSKI:def 1;
    Gij in LSeg(Gi1k,Gij) by RLTOPSP1:68;
    then Gij in LSeg(Gik,Gi1k) \/ LSeg(Gi1k,Gij) by XBOOLE_0:def 3;
    then
A53: Gij in L~<*Gik,Gi1k,Gij*> by SPRECT_1:8;
    Gij in LSeg(co,1) by A50,RLTOPSP1:68;
    hence thesis by A52,A53,XBOOLE_0:def 4;
  end;
  LSeg(co,1) c= L~co by TOPREAL3:19;
  then LSeg(co,1) c= L~LS by A48;
  then LSeg(co,1) /\ L~<*Gik,Gi1k,Gij*> c= {Gij} by A8,A36,XBOOLE_1:26;
  then
A54: L~<*Gik,Gi1k,Gij*> /\ LSeg(co,1) = {Gij} by A51;
A55: rng co c= L~co by A47,SPPOL_2:18;
  reconsider go as non constant s.c.c. being_S-Seq FinSequence of TOP-REAL 2
  by A42,A39,JGRAPH_1:12,JORDAN8:5;
A56: L~go c= L~US by A30,JORDAN3:41;
A57: len go > 1 by A42,NAT_1:13;
  then
A58: len go in dom go by FINSEQ_3:25;
  then
A59: go/.len go = go.len go by PARTFUN1:def 6
    .= Gik by A30,JORDAN3:24;
  reconsider m = len go - 1 as Nat by A58,FINSEQ_3:26;
A60: m+1 = len go;
  then
A61: len go-'1 = m by NAT_D:34;
  m >= 1 by A42,XREAL_1:19;
  then
A62: LSeg(go,m) = LSeg(go/.m,Gik) by A59,A60,TOPREAL1:def 3;
A63: {Gik} c= LSeg(go,m) /\ L~<*Gik,Gi1k,Gij*>
  proof
    let x be object;
    assume x in {Gik};
    then
A64: x = Gik by TARSKI:def 1;
    Gik in LSeg(Gik,Gi1k) by RLTOPSP1:68;
    then Gik in LSeg(Gik,Gi1k) \/ LSeg(Gi1k,Gij) by XBOOLE_0:def 3;
    then
A65: Gik in L~<*Gik,Gi1k,Gij*> by SPRECT_1:8;
    Gik in LSeg(go,m) by A62,RLTOPSP1:68;
    hence thesis by A64,A65,XBOOLE_0:def 4;
  end;
  LSeg(go,m) c= L~go by TOPREAL3:19;
  then LSeg(go,m) c= L~US by A56;
  then LSeg(go,m) /\ L~<*Gik,Gi1k,Gij*> c= {Gik} by A7,A36,XBOOLE_1:26;
  then
A66: LSeg(go,m) /\ L~<*Gik,Gi1k,Gij*> = {Gik} by A63;
A67: go/.1 = US/.1 by A30,SPRECT_3:22
    .= Wmin by JORDAN1F:5;
  then
A68: Wmin in rng go by FINSEQ_6:42;
A69: LS.1 = LS/.1 by A33,PARTFUN1:def 6
    .= Emax by JORDAN1F:6;
A70: L~go /\ L~co c= {go/.1}
  proof
    let x be object;
    assume
A71: x in L~go /\ L~co;
    then
A72: x in L~co by XBOOLE_0:def 4;
A73: now
      assume x = Emax;
      then
A74:  Emax = Gij by A16,A69,A72,JORDAN1E:7;
      G*(len G,j)`1 = Ebo by A4,A19,A13,JORDAN1A:71;
      then Emax`1 <> Ebo by A3,A25,A22,A74,JORDAN1G:7;
      hence contradiction by EUCLID:52;
    end;
    x in L~go by A71,XBOOLE_0:def 4;
    then x in L~US /\ L~LS by A56,A48,A72,XBOOLE_0:def 4;
    then x in {Wmin,Emax} by JORDAN1E:16;
    then x = Wmin or x = Emax by TARSKI:def 2;
    hence thesis by A67,A73,TARSKI:def 1;
  end;
  set W2 = go/.2;
A75: 2 in dom go by A42,FINSEQ_3:25;
  go = mid(US,1,Gik..US) by A38,JORDAN1G:49
    .= US|(Gik..US) by A38,FINSEQ_4:21,FINSEQ_6:116;
  then
A76: W2 = US/.2 by A75,FINSEQ_4:70;
A77: rng go c= L~go by A42,SPPOL_2:18;
A78: go/.1 = LS/.len LS by A67,JORDAN1F:8
    .= co/.len co by A16,JORDAN1J:35;
  {go/.1} c= L~go /\ L~co
  proof
    let x be object;
    assume x in {go/.1};
    then
A79: x = go/.1 by TARSKI:def 1;
    then
A80: x in rng go by FINSEQ_6:42;
    x in rng co by A78,A79,FINSEQ_6:168;
    hence thesis by A77,A55,A80,XBOOLE_0:def 4;
  end;
  then
A81: L~go /\ L~co = {go/.1} by A70;
  now
    per cases;
    suppose
      Gij`1 <> Gik`1 & Gij`2 <> Gik`2;
      then pion is being_S-Seq by A40,TOPREAL3:35;
      then consider pion1 be FinSequence of TOP-REAL 2 such that
A82:  pion1 is_sequence_on G and
A83:  pion1 is being_S-Seq and
A84:  L~pion = L~pion1 and
A85:  pion/.1 = pion1/.1 and
A86:  pion/.len pion = pion1/.len pion1 and
A87:  len pion <= len pion1 by A29,GOBOARD3:2;
      reconsider pion1 as being_S-Seq FinSequence of TOP-REAL 2 by A83;
A88:  (go^'pion1)/.len (go^'pion1) = pion/.len pion by A86,FINSEQ_6:156
        .= pion/.3 by FINSEQ_1:45
        .= co/.1 by A49,FINSEQ_4:18;
A89:  go/.len go = pion1/.1 by A59,A85,FINSEQ_4:18;
A90:  L~go /\ L~pion1 c= {pion1/.1}
      proof
        let x be object;
        assume
A91:    x in L~go /\ L~pion1;
        then
A92:    x in L~pion1 by XBOOLE_0:def 4;
        x in L~go by A91,XBOOLE_0:def 4;
        hence thesis by A7,A36,A59,A56,A84,A89,A92,XBOOLE_0:def 4;
      end;
      len pion1 >= 2+1 by A87,FINSEQ_1:45;
      then
A93:  len pion1 > 1+1 by NAT_1:13;
      then
A94:  rng pion1 c= L~pion1 by SPPOL_2:18;
      {pion1/.1} c= L~go /\ L~pion1
      proof
        let x be object;
        assume x in {pion1/.1};
        then
A95:    x = pion1/.1 by TARSKI:def 1;
        then
A96:    x in rng pion1 by FINSEQ_6:42;
        x in rng go by A89,A95,FINSEQ_6:168;
        hence thesis by A77,A94,A96,XBOOLE_0:def 4;
      end;
      then
A97:  L~go /\ L~pion1 = {pion1/.1} by A90;
      then
A98:  (go^'pion1) is s.n.c. by A89,JORDAN1J:54;
A99:  {Gik} c= LSeg(go,m) /\ LSeg(pion1,1)
      proof
        let x be object;
        assume x in {Gik};
        then
A100:   x = Gik by TARSKI:def 1;
A101:   Gik in LSeg(go,m) by A62,RLTOPSP1:68;
        Gik in LSeg(pion1,1) by A59,A89,A93,TOPREAL1:21;
        hence thesis by A100,A101,XBOOLE_0:def 4;
      end;
      LSeg(pion1,1) c= L~pion by A84,TOPREAL3:19;
      then LSeg(go,len go-'1) /\ LSeg(pion1,1) c={Gik} by A61,A66,XBOOLE_1:27;
      then LSeg(go,len go-'1) /\ LSeg(pion1,1) = { go/.len go } by A59,A61,A99;
      then
A102: go^'pion1 is unfolded by A89,TOPREAL8:34;
      len (go^'pion1) >= len go by TOPREAL8:7;
      then
A103: len (go^'pion1) >= 1+1 by A42,XXREAL_0:2;
      then
A104: len (go^'pion1) > 1+0 by NAT_1:13;
A105: pion/.len pion = pion/.3 by FINSEQ_1:45
        .= co/.1 by A49,FINSEQ_4:18;
A106: {pion1/.len pion1} c= L~co /\ L~pion1
      proof
        let x be object;
        assume x in {pion1/.len pion1};
        then
A107:   x = pion1/.len pion1 by TARSKI:def 1;
        then
A108:   x in rng pion1 by FINSEQ_6:168;
        x in rng co by A86,A105,A107,FINSEQ_6:42;
        hence thesis by A55,A94,A108,XBOOLE_0:def 4;
      end;
      L~co /\ L~pion1 c= {pion1/.len pion1}
      proof
        let x be object;
        assume
A109:   x in L~co /\ L~pion1;
        then
A110:   x in L~pion1 by XBOOLE_0:def 4;
        x in L~co by A109,XBOOLE_0:def 4;
        hence thesis by A8,A36,A49,A48,A84,A86,A105,A110,XBOOLE_0:def 4;
      end;
      then
A111: L~co /\ L~pion1 = {pion1/.len pion1} by A106;
A112: L~(go^'pion1) /\ L~co = (L~go \/ L~pion1) /\ L~co by A89,TOPREAL8:35
        .= {go/.1} \/ {co/.1} by A81,A86,A105,A111,XBOOLE_1:23
        .= {(go^'pion1)/.1} \/ {co/.1} by FINSEQ_6:155
        .= {(go^'pion1)/.1,co/.1} by ENUMSET1:1;
A113: UA is_an_arc_of W-min C,E-max C by JORDAN6:def 8;
      then
A114: UA is connected by JORDAN6:10;
      set godo = go^'pion1^'co;
A115: co/.len co = (go^'pion1)/.1 by A78,FINSEQ_6:155;
A116: go^'pion1 is_sequence_on G by A39,A82,A89,TOPREAL8:12;
      then
A117: godo is_sequence_on G by A45,A88,TOPREAL8:12;
A118: len pion1-1 >= 1 by A93,XREAL_1:19;
      then
A119: len pion1-'1 = len pion1-1 by XREAL_0:def 2;
A120: {Gij} c= LSeg(pion1,len pion1-'1) /\ LSeg(co,1)
      proof
        let x be object;
        assume x in {Gij};
        then
A121:   x = Gij by TARSKI:def 1;
        pion1/.(len pion1-'1+1) = pion/.3 by A86,A119,FINSEQ_1:45
          .= Gij by FINSEQ_4:18;
        then
A122:   Gij in LSeg(pion1,len pion1-'1) by A118,A119,TOPREAL1:21;
        Gij in LSeg(co,1) by A50,RLTOPSP1:68;
        hence thesis by A121,A122,XBOOLE_0:def 4;
      end;
      LSeg(pion1,len pion1-'1) c= L~pion by A84,TOPREAL3:19;
      then LSeg(pion1,len pion1-'1) /\ LSeg(co,1) c= {Gij} by A54,XBOOLE_1:27;
      then
A123: LSeg(pion1,len pion1-'1) /\ LSeg(co,1) = {Gij} by A120;
      len pion1-1+1 <= len pion1;
      then
A124: len pion1-'1 < len pion1 by A119,NAT_1:13;
      len pion1 >= 2+1 by A87,FINSEQ_1:45;
      then
A125: len pion1-2 >= 0 by XREAL_1:19;
      then len pion1-'2+1 = len pion1-2+1 by XREAL_0:def 2
        .= len pion1-'1 by A118,XREAL_0:def 2;
      then
A126: LSeg(go^'pion1,len go+(len pion1-'2)) /\ LSeg(co,1) = {(go^'pion1)
      /.len (go^'pion1)} by A49,A89,A88,A124,A123,TOPREAL8:31;
      rng go /\ rng pion1 c= {pion1/.1} by A77,A94,A97,XBOOLE_1:27;
      then
A127: go^'pion1 is one-to-one by JORDAN1J:55;
      len (go^'pion1)+1-1 = len go+len pion1-1 by FINSEQ_6:139;
      then len (go^'pion1)-1 = len go + (len pion1-2)
        .= len go + (len pion1-'2) by A125,XREAL_0:def 2;
      then
A128: len (go^'pion1)-'1 = len go + (len pion1-'2) by XREAL_0:def 2;
A129: L~Cage(C,n) = L~US \/ L~LS by JORDAN1E:13;
      then
A130: L~US c= L~Cage(C,n) by XBOOLE_1:7;
      then
A131: L~go c=L~Cage(C,n) by A56;
A132: len godo >= len (go^'pion1) by TOPREAL8:7;
      then
A133: 1+1 <= len godo by A103,XXREAL_0:2;
      (go^'pion1) is non trivial by A103,NAT_D:60;
      then reconsider
      godo as non constant standard special_circular_sequence by A133,A88,A117
,A102,A128,A126,A98,A127,A112,A115,JORDAN8:4,5,TOPREAL8:11,33,34;
A134: L~godo = L~(go^'pion1) \/ L~co by A88,TOPREAL8:35
        .= L~go \/ L~pion1 \/ L~co by A89,TOPREAL8:35;
A135: now
        assume
A136:   Gik..US <= 1;
        Gik..US >= 1 by A38,FINSEQ_4:21;
        then Gik..US = 1 by A136,XXREAL_0:1;
        then Gik = US/.1 by A38,FINSEQ_5:38;
        hence contradiction by A15,A37,JORDAN1F:5;
      end;
A137: US is_sequence_on G by JORDAN1G:4;
A138: Gik`1 <= Gi1k`1 by A1,A2,A3,A6,A10,JORDAN1A:18;
      then
A139: W-bound poz = Gik`1 by SPRECT_1:54;
A140: Gi1k`1 = G*(i1,1)`1 by A3,A6,A17,A10,GOBOARD5:2
        .= Gij`1 by A3,A4,A17,A19,GOBOARD5:2;
      then
A141: W-bound pio = Gij`1 by SPRECT_1:54;
      W-bound (poz \/ pio) = min(W-bound poz, W-bound pio) by SPRECT_1:47
        .= Gik`1 by A140,A138,A139,A141,XXREAL_0:def 9;
      then
A142: W-bound L~pion1 = Gik`1 by A84,TOPREAL3:16;
A143: UA c= C by JORDAN6:61;
      Gik`1 >= Wbo by A30,A130,PSCOMP_1:24;
      then
A144: Gik`1 > Wbo by A24,XXREAL_0:1;
A145: len US >= 2 by A14,XXREAL_0:2;
A146: L~go \/ L~co is compact by COMPTS_1:10;
A147: L~LS c= L~Cage(C,n) by A129,XBOOLE_1:7;
      then
A148: L~co c=L~Cage(C,n) by A48;
A149: right_cell(godo,1,G)\L~godo c= RightComp godo by A133,A117,JORDAN9:27;
      2 in dom godo by A133,FINSEQ_3:25;
      then
A150: godo/.2 in rng godo by PARTFUN2:2;
A151: rng godo c= L~godo by A103,A132,SPPOL_2:18,XXREAL_0:2;
A152: godo/.1 = (go^'pion1)/.1 by FINSEQ_6:155
        .= Wmin by A67,FINSEQ_6:155;
A153: W-min C in UA by A113,TOPREAL1:1;
A154: W-min C in C by SPRECT_1:13;
A155: now
        assume W-min C in L~godo;
        then
A156:   W-min C in L~go \/ L~pion1 or W-min C in L~co by A134,XBOOLE_0:def 3;
        per cases by A156,XBOOLE_0:def 3;
        suppose
          W-min C in L~go;
          then C meets L~Cage(C,n) by A131,A154,XBOOLE_0:3;
          hence contradiction by JORDAN10:5;
        end;
        suppose
          W-min C in L~pion1;
          hence contradiction by A9,A36,A84,A153,XBOOLE_0:3;
        end;
        suppose
          W-min C in L~co;
          then C meets L~Cage(C,n) by A148,A154,XBOOLE_0:3;
          hence contradiction by JORDAN10:5;
        end;
      end;
A157: Wmin`1 = Wbo by EUCLID:52;
      set ff = Rotate(Cage(C,n),Wmin);
A158: 1+1 <= len Cage(C,n) by GOBOARD7:34,XXREAL_0:2;
      Wmin in rng Cage(C,n) by SPRECT_2:43;
      then
A159: ff/.1 = Wmin by FINSEQ_6:92;
A160: L~ff = L~Cage(C,n) by REVROT_1:33;
      then (W-max L~ff)..ff > 1 by A159,SPRECT_5:22;
      then (N-min L~ff)..ff > 1 by A159,A160,SPRECT_5:23,XXREAL_0:2;
      then (N-max L~ff)..ff > 1 by A159,A160,SPRECT_5:24,XXREAL_0:2;
      then
A161: Emax..ff > 1 by A159,A160,SPRECT_5:25,XXREAL_0:2;
A162: Cage(C,n) is_sequence_on G by JORDAN9:def 1;
      then
A163: ff is_sequence_on G by REVROT_1:34;
      1+1 <= len Rotate(Cage(C,n),Wmin) by GOBOARD7:34,XXREAL_0:2;
      then right_cell(Rotate(Cage(C,n),Wmin),1) = right_cell(ff,1,GoB ff) by
JORDAN1H:23
        .= right_cell(ff,1,GoB Cage(C,n)) by REVROT_1:28
        .= right_cell(ff,1,G) by JORDAN1H:44
        .= right_cell(ff-:Emax,1,G) by A161,A163,JORDAN1J:53
        .= right_cell(US,1,G) by JORDAN1E:def 1
        .= right_cell(R_Cut(US,Gik),1,G) by A38,A137,A135,JORDAN1J:52
        .= right_cell(go^'pion1,1,G) by A57,A116,JORDAN1J:51
        .= right_cell(godo,1,G) by A104,A117,JORDAN1J:51;
      then W-min C in right_cell(godo,1,G) by JORDAN1I:6;
      then
A164: W-min C in right_cell(godo,1,G)\L~godo by A155,XBOOLE_0:def 5;
A165: E-max C in UA by A113,TOPREAL1:1;
      Wmin in L~go \/ L~co by A77,A68,XBOOLE_0:def 3;
      then
A166: W-min (L~go \/ L~co) = Wmin by A131,A148,A146,JORDAN1J:21,XBOOLE_1:8;
      (W-min (L~go \/ L~co))`1 = W-bound (L~go \/ L~co) by EUCLID:52;
      then W-min (L~go\/L~co\/L~pion1) = W-min (L~go \/ L~co) by A142,A146,A166
,A157,A144,JORDAN1J:33;
      then
A167: W-min L~godo = Wmin by A134,A166,XBOOLE_1:4;
      godo/.2 = (go^'pion1)/.2 by A103,FINSEQ_6:159
        .= US/.2 by A42,A76,FINSEQ_6:159
        .= (US^'LS)/.2 by A145,FINSEQ_6:159
        .= Rotate(Cage(C,n),Wmin)/.2 by JORDAN1E:11;
      then godo/.2 in W-most L~Cage(C,n) by JORDAN1I:25;
      then (godo/.2)`1 = (W-min L~godo)`1 by A167,PSCOMP_1:31
        .= W-bound L~godo by EUCLID:52;
      then godo/.2 in W-most L~godo by A151,A150,SPRECT_2:12;
      then Rotate(godo,W-min L~godo)/.2 in W-most L~godo by A152,A167,
FINSEQ_6:89;
      then reconsider godo as clockwise_oriented non constant standard
      special_circular_sequence by JORDAN1I:25;
      len US in dom US by FINSEQ_5:6;
      then
A168: US.len US = US/.len US by PARTFUN1:def 6
        .= Emax by JORDAN1F:7;
A169: east_halfline E-max C misses L~go
      proof
        assume east_halfline E-max C meets L~go;
        then consider p be object such that
A170:   p in east_halfline E-max C and
A171:   p in L~go by XBOOLE_0:3;
        reconsider p as Point of TOP-REAL 2 by A170;
        p in L~US by A56,A171;
        then p in east_halfline E-max C /\ L~Cage(C,n) by A130,A170,
XBOOLE_0:def 4;
        then
A172:   p`1 = Ebo by JORDAN1A:83,PSCOMP_1:50;
        then
A173:   p = Emax by A56,A171,JORDAN1J:46;
        then Emax = Gik by A30,A168,A171,JORDAN1J:43;
        then Gik`1 = G*(len G,k)`1 by A6,A10,A13,A172,A173,JORDAN1A:71;
        hence contradiction by A2,A3,A12,A41,JORDAN1G:7;
      end;
      now
        assume east_halfline E-max C meets L~godo;
        then
A174:   east_halfline E-max C meets (L~go \/ L~pion1) or east_halfline
        E-max C meets L~co by A134,XBOOLE_1:70;
        per cases by A174,XBOOLE_1:70;
        suppose
          east_halfline E-max C meets L~go;
          hence contradiction by A169;
        end;
        suppose
          east_halfline E-max C meets L~pion1;
          then consider p be object such that
A175:     p in east_halfline E-max C and
A176:     p in L~pion1 by XBOOLE_0:3;
          reconsider p as Point of TOP-REAL 2 by A175;
A177:     p`2 = (E-max C)`2 by A175,TOPREAL1:def 11;
A178:     now
            per cases by A36,A84,A176,XBOOLE_0:def 3;
            suppose
              p in poz;
              hence p`1 <= Gi1k`1 by A138,TOPREAL1:3;
            end;
            suppose
              p in pio;
              hence p`1 <= Gi1k`1 by A140,GOBOARD7:5;
            end;
          end;
          i1+1 <= len G by A3,NAT_1:13;
          then i1+1-1 <= len G-1 by XREAL_1:9;
          then
A179:     i1 <= len G-'1 by XREAL_0:def 2;
          len G-'1 <= len G by NAT_D:35;
          then Gi1k`1 <= G*(len G-'1,1)`1 by A6,A17,A10,A13,A21,A179,
JORDAN1A:18;
          then p`1 <= G*(len G-'1,1)`1 by A178,XXREAL_0:2;
          then p`1 <= E-bound C by A21,JORDAN8:12;
          then
A180:     p`1 <= (E-max C)`1 by EUCLID:52;
          p`1 >= (E-max C)`1 by A175,TOPREAL1:def 11;
          then p`1 = (E-max C)`1 by A180,XXREAL_0:1;
          then p = E-max C by A177,TOPREAL3:6;
          hence contradiction by A9,A36,A84,A165,A176,XBOOLE_0:3;
        end;
        suppose
          east_halfline E-max C meets L~co;
          then consider p be object such that
A181:     p in east_halfline E-max C and
A182:     p in L~co by XBOOLE_0:3;
          reconsider p as Point of TOP-REAL 2 by A181;
A183:     p in LSeg(co,Index(p,co)) by A182,JORDAN3:9;
          consider t be Nat such that
A184:     t in dom LS and
A185:     LS.t = Gij by A44,FINSEQ_2:10;
          1 <= t by A184,FINSEQ_3:25;
          then
A186:     1 < t by A46,A185,XXREAL_0:1;
          t <= len LS by A184,FINSEQ_3:25;
          then Index(Gij,LS)+1 = t by A185,A186,JORDAN3:12;
          then
A187:     len L_Cut(LS,Gij) = len LS-Index(Gij,LS) by A16,A185,JORDAN3:26;
          Index(p,co) < len co by A182,JORDAN3:8;
          then Index(p,co) < len LS-'Index(Gij,LS) by A187,XREAL_0:def 2;
          then Index(p,co)+1 <= len LS-'Index(Gij,LS) by NAT_1:13;
          then
A188:     Index(p,co) <= len LS-'Index(Gij,LS)-1 by XREAL_1:19;
A189:     co = mid(LS,Gij..LS,len LS) by A44,JORDAN1J:37;
          p in L~LS by A48,A182;
          then p in east_halfline E-max C /\ L~Cage(C,n) by A147,A181,
XBOOLE_0:def 4;
          then
A190:     p`1 = Ebo by JORDAN1A:83,PSCOMP_1:50;
A191:     Index(Gij,LS)+1 = Gij..LS by A46,A44,JORDAN1J:56;
          0+Index(Gij,LS) < len LS by A16,JORDAN3:8;
          then len LS-Index(Gij,LS) > 0 by XREAL_1:20;
          then Index(p,co) <= len LS-Index(Gij,LS)-1 by A188,XREAL_0:def 2;
          then Index(p,co) <= len LS-Gij..LS by A191;
          then Index(p,co) <= len LS-'Gij..LS by XREAL_0:def 2;
          then
A192:     Index(p,co) < len LS-'(Gij..LS)+1 by NAT_1:13;
A193:     1<=Index(p,co) by A182,JORDAN3:8;
A194:     Gij..LS<=len LS by A44,FINSEQ_4:21;
          Gij..LS <> len LS by A43,A44,FINSEQ_4:19;
          then
A195:     Gij..LS < len LS by A194,XXREAL_0:1;
A196:     1+1 <= len LS by A31,XXREAL_0:2;
          then
A197:     2 in dom LS by FINSEQ_3:25;
          set tt = Index(p,co)+(Gij..LS)-'1;
          set RC = Rotate(Cage(C,n),Emax);
A198:     E-max C in right_cell(RC,1) by JORDAN1I:7;
A199:     GoB RC = GoB Cage(C,n) by REVROT_1:28
            .= G by JORDAN1H:44;
A200:     L~RC = L~Cage(C,n) by REVROT_1:33;
          consider jj2 be Nat such that
A201:     1 <= jj2 and
A202:     jj2 <= width G and
A203:     Emax = G*(len G,jj2) by JORDAN1D:25;
A204:     len G >= 4 by JORDAN8:10;
          then len G >= 1 by XXREAL_0:2;
          then
A205:     [len G,jj2] in Indices G by A201,A202,MATRIX_0:30;
A206:     len RC = len Cage(C,n) by FINSEQ_6:179;
          LS = RC-:Wmin by JORDAN1G:18;
          then
A207:     LSeg(LS,1) = LSeg(RC,1) by A196,SPPOL_2:9;
A208:     Emax in rng Cage(C,n) by SPRECT_2:46;
          RC is_sequence_on G by A162,REVROT_1:34;
          then consider ii,jj be Nat such that
A209:     [ii,jj+1] in Indices G and
A210:     [ii,jj] in Indices G and
A211:     RC/.1 = G*(ii,jj+1) and
A212:     RC/.(1+1) = G*(ii,jj) by A158,A200,A206,A208,FINSEQ_6:92,JORDAN1I:23;
A213:     jj+1+1 <> jj;
A214:     1 <= jj by A210,MATRIX_0:32;
          RC/.1 = E-max L~RC by A200,A208,FINSEQ_6:92;
          then
A215:     ii = len G by A200,A209,A211,A203,A205,GOBOARD1:5;
          then ii-1 >= 4-1 by A204,XREAL_1:9;
          then
A216:     ii-1 >= 1 by XXREAL_0:2;
          then
A217:     1 <= ii-'1 by XREAL_0:def 2;
A218:     jj <= width G by A210,MATRIX_0:32;
          then
A219:     G*(len G,jj)`1 = Ebo by A13,A214,JORDAN1A:71;
A220:     jj+1 <= width G by A209,MATRIX_0:32;
          ii+1 <> ii;
          then
A221:     right_cell(RC,1) = cell(G,ii-'1,jj) by A158,A206,A199,A209,A210,A211
,A212,A213,GOBOARD5:def 6;
A222:     ii <= len G by A210,MATRIX_0:32;
A223:     1 <= ii by A210,MATRIX_0:32;
A224:     ii <= len G by A209,MATRIX_0:32;
A225:     1 <= jj+1 by A209,MATRIX_0:32;
          then
A226:     Ebo = G*(len G,jj+1)`1 by A13,A220,JORDAN1A:71;
A227:     1 <= ii by A209,MATRIX_0:32;
          then
A228:     ii-'1+1 = ii by XREAL_1:235;
          then
A229:     ii-'1 < len G by A224,NAT_1:13;
          then
A230:     G*(ii-'1,jj+1)`2 = G*(1,jj+1)`2 by A225,A220,A217,GOBOARD5:1
            .= G*(ii,jj+1)`2 by A227,A224,A225,A220,GOBOARD5:1;
A231:     (E-max C)`2 = p`2 by A181,TOPREAL1:def 11;
          then
A232:     p`2 <= G*(ii-'1,jj+1)`2 by A198,A224,A220,A214,A221,A228,A216,
JORDAN9:17;
A233:     G*(ii-'1,jj)`2 = G*(1,jj)`2 by A214,A218,A217,A229,GOBOARD5:1
            .= G*(ii,jj)`2 by A223,A222,A214,A218,GOBOARD5:1;
          G*(ii-'1,jj)`2 <= p`2 by A231,A198,A224,A220,A214,A221,A228,A216,
JORDAN9:17;
          then p in LSeg(RC/.1,RC/.(1+1)) by A190,A211,A212,A215,A232,A233,A230
,A219,A226,GOBOARD7:7;
          then
A234:     p in LSeg(LS,1) by A158,A207,A206,TOPREAL1:def 3;
          1<=Gij..LS by A44,FINSEQ_4:21;
          then
A235:     LSeg(mid(LS,Gij..LS,len LS),Index(p,co)) = LSeg(LS,Index(p,co)
          +(Gij..LS)-'1) by A195,A193,A192,JORDAN4:19;
          1<=Index(Gij,LS) by A16,JORDAN3:8;
          then
A236:     1+1 <= Gij..LS by A191,XREAL_1:7;
          then Index(p,co)+Gij..LS >= 1+1+1 by A193,XREAL_1:7;
          then Index(p,co)+Gij..LS-1 >= 1+1+1-1 by XREAL_1:9;
          then
A237:     tt >= 1+1 by XREAL_0:def 2;
          now
            per cases by A237,XXREAL_0:1;
            suppose
              tt > 1+1;
              then LSeg(LS,1) misses LSeg(LS,tt) by TOPREAL1:def 7;
              hence contradiction by A234,A183,A189,A235,XBOOLE_0:3;
            end;
            suppose
A238:         tt = 1+1;
              then 1+1 = Index(p,co)+(Gij..LS)-1 by XREAL_0:def 2;
              then 1+1+1 = Index(p,co)+(Gij..LS);
              then
A239:         Gij..LS = 2 by A193,A236,JORDAN1E:6;
              LSeg(LS,1) /\ LSeg(LS,tt) = {LS/.2} by A31,A238,TOPREAL1:def 6;
              then p in {LS/.2} by A234,A183,A189,A235,XBOOLE_0:def 4;
              then
A240:         p = LS/.2 by TARSKI:def 1;
              then
A241:         p in rng LS by A197,PARTFUN2:2;
              p..LS = 2 by A197,A240,FINSEQ_5:41;
              then p = Gij by A44,A239,A241,FINSEQ_5:9;
              then Gij`1 = Ebo by A240,JORDAN1G:32;
              then Gij`1 = G*(len G,j)`1 by A4,A19,A13,JORDAN1A:71;
              hence contradiction by A3,A25,A22,JORDAN1G:7;
            end;
          end;
          hence contradiction;
        end;
      end;
      then east_halfline E-max C c= (L~godo)` by SUBSET_1:23;
      then consider W be Subset of TOP-REAL 2 such that
A242: W is_a_component_of (L~godo)` and
A243: east_halfline E-max C c= W by GOBOARD9:3;
      W is not bounded by A243,JORDAN2C:121,RLTOPSP1:42;
      then W is_outside_component_of L~godo by A242,JORDAN2C:def 3;
      then W c= UBD L~godo by JORDAN2C:23;
      then
A244: east_halfline E-max C c= UBD L~godo by A243;
      E-max C in east_halfline E-max C by TOPREAL1:38;
      then E-max C in UBD L~godo by A244;
      then E-max C in LeftComp godo by GOBRD14:36;
      then UA meets L~godo by A114,A153,A165,A149,A164,JORDAN1J:36;
      then
A245: UA meets (L~go \/ L~pion1) or UA meets L~co by A134,XBOOLE_1:70;
      now
        per cases by A245,XBOOLE_1:70;
        suppose
          UA meets L~go;
          then UA meets L~Cage(C,n) by A56,A130,XBOOLE_1:1,63;
          hence contradiction by A143,JORDAN10:5,XBOOLE_1:63;
        end;
        suppose
          UA meets L~pion1;
          hence contradiction by A9,A36,A84;
        end;
        suppose
          UA meets L~co;
          then UA meets L~Cage(C,n) by A48,A147,XBOOLE_1:1,63;
          hence contradiction by A143,JORDAN10:5,XBOOLE_1:63;
        end;
      end;
      hence contradiction;
    end;
    suppose
      Gij`1 = Gik`1;
      then
A246: i1 = i2 by A25,A12,JORDAN1G:7;
      then poz = {Gi1k} by RLTOPSP1:70;
      then poz c= pio by A27,ZFMISC_1:31;
      then pio \/ poz = pio by XBOOLE_1:12;
      hence contradiction by A1,A3,A4,A5,A6,A7,A8,A9,A246,JORDAN1J:59;
    end;
    suppose
      Gij`2 = Gik`2;
      then
A247: j = k by A25,A12,JORDAN1G:6;
      then pio = {Gi1k} by RLTOPSP1:70;
      then pio c= poz by A26,ZFMISC_1:31;
      then pio \/ poz = poz by XBOOLE_1:12;
      hence contradiction by A1,A2,A3,A4,A6,A7,A8,A9,A247,Th37;
    end;
  end;
  hence contradiction;
end;
