reserve m,n,i,i2,j for Nat,
  r,r1,r2,s,t for Real,
  x,y,z for object;
reserve p,p1,p2,p3,q,q1,q2,q3,q4 for Point of TOP-REAL n;
reserve u for Point of Euclid n;

theorem Th33:
  for x being Element of REAL n,f being FinSequence st x<> 0*n & x
  =f holds ex i being Element of NAT st 1<=i & i<=n & f.i<>0
proof
  let x be Element of REAL n,f be FinSequence;
  assume that
A1: x<> 0*n and
A2: x=f;
A3: len f=n by A2,CARD_1:def 7;
  assume
A4: not ex i being Element of NAT st 1<=i & i<=n & f.i<>0;
  for z being object holds z in f iff
   ex x,y being object st x in Seg n & y in {0} & z = [ x,y]
  proof
    let z be object;
    hereby
      assume
A5:   z in f;
      then consider x0,y0 being object such that
A6:   z = [x0,y0] by RELAT_1:def 1;
A7:   y0=f.x0 by A5,A6,FUNCT_1:1;
A8:   x0 in dom f by A5,A6,XTUPLE_0:def 12;
      then reconsider n1=x0 as Element of NAT;
A9:   x0 in Seg len f by A8,FINSEQ_1:def 3;
      then 1<=n1 & n1<=len f by FINSEQ_1:1;
      then f.n1=0 by A3,A4;
      then y0 in {0} by A7,TARSKI:def 1;
      hence ex x,y being object
          st x in Seg n & y in {0} & z = [x,y] by A3,A6,A9;
    end;
    given x,y being object such that
A10: x in Seg n and
A11: y in {0} and
A12: z = [x,y];
    reconsider n1=x as Element of NAT by A10;
A13: n1<=n by A10,FINSEQ_1:1;
A14: x in dom f by A3,A10,FINSEQ_1:def 3;
    y=0 & 1<=n1 by A10,A11,FINSEQ_1:1,TARSKI:def 1;
    then y=f.x by A4,A13;
    hence thesis by A12,A14,FUNCT_1:1;
  end;
  then f=[:Seg n,{0}:] by ZFMISC_1:def 2;
  hence contradiction by A1,A2,FUNCOP_1:def 2;
end;
