reserve i, j, m, n, k for Nat,
  x, y for set,
  K for Field,
  a,a1 for Element of K;
reserve V1,V2,V3 for finite-dimensional VectSp of K,
  f for Function of V1,V2,

  b1,b19 for OrdBasis of V1,
  B1 for FinSequence of V1,
  b2 for OrdBasis of V2,
  B2 for FinSequence of V2,

  B3 for FinSequence of V3,
  v1,w1 for Element of V1,
  R,R1,R2 for FinSequence of V1,
  p,p1,p2 for FinSequence of K;

theorem Th46:
  for M be OrdBasis of (len b2)-VectSp_over K st 
  M = MX2FinS 1.(K,len b2) 
  for v1 be Vector of (len b2)-VectSp_over K holds v1|--M = v1
proof
  let M be OrdBasis of (len b2)-VectSp_over K such that
A1: M = MX2FinS 1.(K,len b2);
  let v1 be Vector of (len b2)-VectSp_over K;
  set vM=v1|--M;
  consider KL be Linear_Combination of (len b2)-VectSp_over K such that
A2: v1 = Sum(KL) & Carrier KL c= rng M and
A3: for k st 1<=k & k<=len (v1|--M) holds vM/.k=KL.(M/.k) by MATRLIN:def 7;
  reconsider t1=v1 as Element of (len b2)-tuples_on the carrier of K by
MATRIX13:102;
A4: len t1=len b2 by CARD_1:def 7;
A5: len M=dim ((len b2)-VectSp_over K) & dim ((len b2)-VectSp_over K) =len
  b2 by Th21,MATRIX13:112;
A6: len vM=len M by MATRLIN:def 7;
  now
A7: dom M= dom vM by A6,FINSEQ_3:29;
A8: the_rank_of 1.(K,len b2)=len b2 by Lm6;
    set F=FinS2MX(KL (#) M);
A9: Indices 1.(K,len b2)=[:Seg len b2,Seg len b2:] by MATRIX_0:24;
    let i such that
A10: 1<=i & i<=len t1;
A11: i in Seg len b2 by A4,A10;
    then
A12: [i,i] in [:Seg len b2,Seg len b2:] by ZFMISC_1:87;
A13: width 1.(K,len b2)=len b2 by MATRIX_0:24;
    then
A14: Line(1.(K,len b2),i).i = 1.(K,len b2)*(i,i) by A11,MATRIX_0:def 7
      .= 1_K by A9,A12,MATRIX_1:def 3;
A15: len Col(F,i)=len F by CARD_1:def 7;
    then
A16: dom Col(F,i)=dom F by FINSEQ_3:29;
A17: len F=len M by VECTSP_6:def 5;
    then
A18: dom F= dom M by FINSEQ_3:29;
A19: i in dom Col(F,i) by A4,A5,A10,A17,A15,FINSEQ_3:25;
A20: width F=len b2 by A5,A17,MATRIX_0:24;
    now
      let j such that
A21:  j in dom Col(F,i) and
A22:  j<>i;
A23:  dom Col(F,i)=Seg len b2 by A5,A17,A15,FINSEQ_1:def 3;
      then
A24:  [j,i] in [:Seg len b2,Seg len b2:] by A11,A21,ZFMISC_1:87;
A25:  Line(F,j) = (KL (#) M).j by A5,A17,A21,A23,MATRIX_0:52
        .= KL.(M/.j) * M/.j by A16,A21,VECTSP_6:def 5;
A26:  Col(F,i).j = F*(j,i) by A16,A21,MATRIX_0:def 8
        .= Line(F,j).i by A11,A20,MATRIX_0:def 7;
A27:  Line(1.(K,len b2),j).i = 1.(K,len b2)*(j,i) by A11,A13,MATRIX_0:def 7
        .= 0.K by A9,A22,A24,MATRIX_1:def 3;
      M/.j = M.j by A16,A18,A21,PARTFUN1:def 6
        .= Line(1.(K,len b2),j) by A1,A21,A23,MATRIX_0:52;
      hence Col(F,i).j = (KL.(M/.j) * Line(1.(K,len b2),j)).i by A13,A26,A25,
MATRIX13:102
        .= KL.(M/.j)*0.K by A11,A13,A27,FVSUM_1:51
        .= 0.K;
    end;
    then
A28: Col(F,i).i = Sum Col(F,i) by A19,MATRIX_3:12
      .= v1.i by A1,A2,A11,A8,MATRIX13:105,107;
A29: Line(F,i) = (KL (#) M).i by A5,A11,A17,MATRIX_0:52
      .= KL.(M/.i) * M/.i by A19,A16,VECTSP_6:def 5;
A30: Col(F,i).i = F*(i,i) by A19,A16,MATRIX_0:def 8
      .= Line(F,i).i by A11,A20,MATRIX_0:def 7;
    M/.i = M.i by A19,A16,A18,PARTFUN1:def 6
      .= Line(1.(K,len b2),i) by A1,A11,MATRIX_0:52;
    then Col(F,i).i = (KL.(M/.i) * Line(1.(K,len b2),i)).i by A30,A13,A29,
MATRIX13:102
      .= KL.(M/.i)*1_K by A11,A13,A14,FVSUM_1:51
      .= KL.(M/.i);
    hence t1.i = vM/.i by A3,A4,A6,A5,A10,A28
      .= vM.i by A19,A16,A18,A7,PARTFUN1:def 6;
  end;
  hence thesis by A4,A6,A5,FINSEQ_1:14;
end;
