reserve m, n for Nat;

theorem Th46:
  for p being Prime holds (PFactors p) * <*p*> = <*p*>
proof
  let p be Prime;
  set f = <*p*>, g = PFactors p;
A1: dom (g * f) = {1}
  proof
    thus dom (g * f) c= {1}
    proof
      let x be object;
      assume x in dom (g * f);
      then x in dom f by FUNCT_1:11;
      hence thesis by FINSEQ_1:2,38;
    end;
    let x be object;
    assume
A2: x in {1};
    then x = 1 by TARSKI:def 1;
    then f.x = p;
    then f.x in SetPrimes by NEWTON:def 6;
    then
A3: f.x in dom g by PARTFUN1:def 2;
    x in dom f by A2,FINSEQ_1:2,38;
    hence thesis by A3,FUNCT_1:11;
  end;
A4: for x being object st x in dom (g * f) holds (g * f).x = f.x
  proof
    let x be object;
    (pfexp p).p <> 0 by NAT_3:38;
    then
A5: p in support pfexp p by PRE_POLY:def 7;
    assume
A6: x in dom (g * f);
    then
A7: x = 1 by A1,TARSKI:def 1;
    then (g * f).1 = g.(f.1) by A6,FUNCT_1:12
      .= g.p
      .= p by A5,Def6
      .= f.1;
    hence thesis by A7;
  end;
  dom f = {1} by FINSEQ_1:2,38;
  hence thesis by A1,A4,FUNCT_1:2;
end;
