
theorem Th45:
  for x being Real st x >= 2 holds
  Product Sgm{p where p is prime Element of NAT:p <= x} <= 4 to_power (x-1)
proof
  let x be Real;
  set A={p where p is prime Element of NAT:p<=x};
A1: A is finite
  proof
    ex m being Element of NAT st x<m
    proof
      set m=|.[/x\].|+1;
      take m;
      [/x\]<=|.[/x\].| & |.[/x\].|<|.[/x\].|+1 by ABSVALUE:4,NAT_1:13;
      then x<=[/x\] & [/x\]<|.[/x\].|+1 by INT_1:def 7,XXREAL_0:2;
      hence thesis by XXREAL_0:2;
    end;
    then consider m being Element of NAT such that
A2: x<m;
    set B=SetPrimenumber m;
    A c= B
    proof
      let y be object;
      assume y in {p where p is prime Element of NAT:p<=x};
      then consider y9 be prime Element of NAT such that
A3:   y9=y and
A4:   y9<=x;
      y9<m by A2,A4,XXREAL_0:2;
      hence thesis by A3,NEWTON:def 7;
    end;
    hence thesis;
  end;
A5: A is real-membered
  proof
    let y be object;
    y in A implies y is real
    proof
      assume y in {p where p is prime Element of NAT:p<=x};
      then ex y9 being prime Element of NAT st y9=y & y9<=x;
      hence thesis;
    end;
    hence thesis;
  end;
  assume
A6: x>=2;
  A is non empty
  proof
    assume
A7: A is empty;
    2 in A by A6,INT_2:28;
    hence contradiction by A7;
  end;
  then reconsider A as finite non empty real-membered set by A1,A5;
  set q = max A;
  q in A by XXREAL_2:def 8;
  then
A8: ex q9 being prime Element of NAT st q9=q & q9<=x;
  then reconsider q as Prime;
  for y being object holds y in {p where p is prime Element of NAT:p<=q} iff
  y in {p where p is prime Element of NAT:p<=x}
  proof
    let y be object;
    hereby
      assume y in {p where p is prime Element of NAT:p<=q};
      then consider y9 being prime Element of NAT such that
A9:   y9=y and
A10:  y9<=q;
      y9<=x by A8,A10,XXREAL_0:2;
      hence y in {p where p is prime Element of NAT:p<=x} by A9;
    end;
    assume
A11: y in {p where p is prime Element of NAT:p<=x};
    then consider y9 being prime Element of NAT such that
A12: y9=y and
    y9<=x;
    y9<=q by A11,A12,XXREAL_2:def 8;
    hence thesis by A12;
  end;
  then
A13: {p where p is prime Element of NAT:p<=q}= {p where p is prime Element
  of NAT:p<=x} by TARSKI:2;
A14: 4 to_power (q-1)<=4 to_power (x-1)
  proof
    per cases by A8,XXREAL_0:1;
    suppose
      q=x;
      hence thesis;
    end;
    suppose
      q<x;
      then q-1<x-1 by XREAL_1:14;
      hence thesis by POWER:39;
    end;
  end;
  Product Sgm{p where p is prime Element of NAT:p<=x} <= (4 to_power (x-1 ))
  proof
    set b = 4 to_power (q-1);
    set a = Product Sgm{p where p is prime Element of NAT:p<=q};
    set n=q-'1;
    q>1 by Lm1;
    then q-'1=q-1 by XREAL_1:233;
    then q=n+1;
    then a<=b by Th44;
    hence thesis by A13,A14,XXREAL_0:2;
  end;
  hence thesis;
end;
