reserve E, F, G,S,T,W,Y for RealNormSpace;
reserve f,f1,f2 for PartFunc of S,T;
reserve Z for Subset of S;
reserve i,n for Nat;

theorem Th47:
  for E,F be RealNormSpace
  ex L20 be Lipschitzian LinearOperator of F,[:E,F:]
  st for dy be Point of F holds L20.dy = [0.E,dy]
proof
  let E,F be RealNormSpace;

  defpred P2[object , object] means
  ex dx be Point of F
  st dx = $1 & $2 = [0.E,dx];

  A1: for x be object st x in the carrier of F
      holds
        ex y be object
        st y in the carrier of [:E,F:] & P2[x,y]
  proof
    let x be object;
    assume x in the carrier of F;
    then reconsider V1 = x as Point of F;
    take y = [0.E, V1];
    thus thesis;
  end;

  consider L1 be Function of the carrier of F, the carrier of [:E,F:]
  such that
  A2: for x be object st x in the carrier of F
      holds P2[x, L1.x] from FUNCT_2:sch 1(A1);

  A3: for dx be Point of F holds L1.dx = [0.E,dx]
  proof
    let dx be Point of F;
    ex V1 be Point of F
    st V1 = dx & L1.dx = [0.E, V1] by A2;
    hence L1.dx = [0.E, dx];
  end;

  for x, y be Element of F
  holds L1.(x + y) = L1.x + L1.y
  proof
    let x, y be Element of F;
    A4: L1.x = [0.E,x] by A3;
    A5: L1.y = [0.E,y] by A3;

    thus L1.(x + y)
     = [0.E, x + y] by A3
    .= [0.E + 0.E, x + y] by RLVECT_1:4
    .= L1.x + L1.y by A4,A5,PRVECT_3:18;
  end;
  then A6: L1 is additive;

  for x be VECTOR of F, a be Real holds L1.(a*x) = a * L1.x
  proof
    let x be VECTOR of F, a be Real;
    A7: L1.x = [0.E,x] by A3;
    thus L1.(a*x)
     = [0.E,a*x] by A3
    .= [a * 0.E, a*x] by RLVECT_1:10
    .= a * L1.x by A7,PRVECT_3:18;
  end;
  then reconsider L1 as LinearOperator of F,[:E,F:] by A6,LOPBAN_1:def 5;

  set K = 1;

  for x be VECTOR of F holds ||.L1.x.|| <= K * ||.x.||
  proof
    let x be VECTOR of F;
    L1.x = [0.E,x] by A3;
    then ||.L1.x.|| <= ||.x.|| + ||.0.E.|| by Th17;
    then ||.L1.x.|| <= K * ||.x.|| + 0 by NORMSP_1:1;
    hence thesis;
  end;
  then L1 is Lipschitzian by LOPBAN_1:def 8;
  hence thesis by A3;
end;
