reserve A,A1,A2,B,C,D for Ordinal,
  X,Y for set,
  x,y,a,b,c for object,
  L,L1,L2,L3 for Sequence,
  f for Function;
reserve fi,psi for Ordinal-Sequence;

theorem
  exp(A,1) = A & exp(1,A) = 1
proof
  defpred P[Ordinal] means exp(1,$1) = 1;
A1: for A st P[A] holds P[succ A]
  proof
    let A;
    assume exp(1,A) = 1;
    hence exp(1,succ A) = 1*^1 by Th44
      .= 1 by Th39;
  end;
  thus exp(A,1) = A*^exp(A,0) by Lm1,Th44
    .= A*^1 by Th43
    .= A by Th39;
A2: for A st A <> 0 & A is limit_ordinal & for B st B in A holds P[B] holds
  P[A]
  proof
    deffunc F(Ordinal) = exp(1,$1);
    let A such that
A3: A <> 0 and
A4: A is limit_ordinal and
A5: for B st B in A holds exp(1,B) = 1;
    consider fi such that
A6: dom fi = A & for B st B in A holds fi.B = F(B) from OSLambda;
A7: rng fi c= { 1 }
    proof
      let x be object;
      assume x in rng fi;
      then consider y being object such that
A8:   y in dom fi and
A9:   x = fi.y by FUNCT_1:def 3;
      reconsider y as Ordinal by A8;
      x = exp(1,y) by A6,A8,A9
        .= 1 by A5,A6,A8;
      hence thesis by TARSKI:def 1;
    end;
    now
      set x = the Element of A;
      thus 0 <> 1;
      let B,C such that
A10:  B in 1 & 1 in C;
      reconsider x as Ordinal;
      take D = x;
      thus D in dom fi by A3,A6;
      let E be Ordinal;
      assume that
      D c= E and
A11:  E in dom fi;
      fi.E in rng fi by A11,FUNCT_1:def 3;
      hence B in fi.E & fi.E in C by A7,A10,TARSKI:def 1;
    end;
    then
A12: 1 is_limes_of fi by Def9;
    exp(1,A) = lim fi by A3,A4,A6,Th45;
    hence thesis by A12,Def10;
  end;
A13: P[0] by Th43;
  for A holds P[A] from OrdinalInd(A13,A1,A2);
  hence thesis;
end;
