reserve x,x0,x1,y,y0,y1,z,z0,z1,r,r1,s,p,p1 for Real;
reserve u,u0 for Element of REAL 3;
reserve n for Element of NAT;
reserve s1 for Real_Sequence;
reserve f,f1,f2 for PartFunc of REAL 3,REAL;
reserve R,R1 for RestFunc;
reserve L,L1 for LinearFunc;

theorem
  f1 is_hpartial_differentiable`11_in u0 &
  f2 is_hpartial_differentiable`11_in u0 implies
  pdiff1(f1,1)+pdiff1(f2,1) is_partial_differentiable_in u0,1 &
  partdiff(pdiff1(f1,1)+pdiff1(f2,1),u0,1)
  = hpartdiff11(f1,u0) + hpartdiff11(f2,u0)
proof
    assume that
A1: f1 is_hpartial_differentiable`11_in u0 and
A2: f2 is_hpartial_differentiable`11_in u0;
A3: pdiff1(f1,1) is_partial_differentiable_in u0,1 by A1,Th19;
A4: pdiff1(f2,1) is_partial_differentiable_in u0,1 by A2,Th19;then
 pdiff1(f1,1)+pdiff1(f2,1) is_partial_differentiable_in u0,1 &
    partdiff(pdiff1(f1,1)+pdiff1(f2,1),u0,1)
    = partdiff(pdiff1(f1,1),u0,1) + partdiff(pdiff1(f2,1),u0,1)
    by A3,PDIFF_1:29;
    then partdiff(pdiff1(f1,1)+pdiff1(f2,1),u0,1)
    = hpartdiff11(f1,u0) + partdiff(pdiff1(f2,1),u0,1) by A1,Th28
   .= hpartdiff11(f1,u0) + hpartdiff11(f2,u0) by A2,Th28;
    hence thesis by A3,A4,PDIFF_1:29;
end;
