reserve r, s, t, g for Real,

          r3, r1, r2, q3, p3 for Real;
reserve T for TopStruct,
  f for RealMap of T;
reserve p for Point of TOP-REAL 2,
  P for Subset of TOP-REAL 2,
  Z for non empty Subset of TOP-REAL 2,
  X for non empty compact Subset of TOP-REAL 2;

theorem Th46:
  (SE-corner X)`2 <= (E-min X)`2 & (SE-corner X)`2 <= (E-max X)`2
& (SE-corner X)`2 <= (NE-corner X)`2 & (E-min X)`2 <= (E-max X)`2 & (E-min X)`2
  <= (NE-corner X)`2 & (E-max X)`2 <= (NE-corner X)`2
proof
  set LX = E-most X;
A1: (E-min X)`2 = lower_bound (proj2|LX) by EUCLID:52;
A2: (SE-corner X)`2 = lower_bound (proj2|X) by EUCLID:52;
  hence (SE-corner X)`2 <= (E-min X)`2 by A1,Th16,XBOOLE_1:17;
A3: (E-max X)`2 = upper_bound (proj2|LX) by EUCLID:52;
  then
A4: (E-min X)`2 <= (E-max X)`2 by A1,Th7;
  (SE-corner X)`2 <= (E-min X)`2 by A2,A1,Th16,XBOOLE_1:17;
  hence
A5: (SE-corner X)`2 <= (E-max X)`2 by A4,XXREAL_0:2;
A6: (NE-corner X)`2 = upper_bound (proj2|X) by EUCLID:52;
  then
A7: (E-max X)`2 <= (NE-corner X)`2 by A3,Th17,XBOOLE_1:17;
  hence (SE-corner X)`2 <= (NE-corner X)`2 by A5,XXREAL_0:2;
  thus (E-min X)`2 <= (E-max X)`2 by A1,A3,Th7;
  thus (E-min X)`2 <= (NE-corner X)`2 by A4,A7,XXREAL_0:2;
  thus thesis by A3,A6,Th17,XBOOLE_1:17;
end;
