reserve A for Tolerance_Space,
  X, Y for Subset of A;
reserve A for Approximation_Space,
  X for Subset of A;
reserve A for finite Tolerance_Space,
  X for Subset of A,
  x for Element of A;
reserve A for finite Approximation_Space,
  X, Y for Subset of A,
  x for Element of A;

theorem
  MemberFunc (X`,A).x = 1 - (MemberFunc (X,A).x)
proof
A1: [#]A /\ Class (the InternalRel of A, x) = Class (the InternalRel of A, x
  ) by XBOOLE_1:28;
  MemberFunc (X`,A).x = card (([#]A \ X) /\ Class (the InternalRel of A, x
  )) / (card Class (the InternalRel of A, x)) by Def9
    .= (card (([#]A /\ Class (the InternalRel of A, x)) \ (X /\ Class (the
InternalRel of A, x)))) / (card Class (the InternalRel of A, x)) by XBOOLE_1:50
    .= (card ([#]A /\ Class (the InternalRel of A, x)) - card (X /\ Class (
  the InternalRel of A, x))) / (card Class (the InternalRel of A, x)) by A1,
CARD_2:44,XBOOLE_1:17
    .= card ([#]A /\ Class (the InternalRel of A, x))/ (card Class (the
  InternalRel of A, x)) - (card (X /\ Class (the InternalRel of A, x)) / (card
  Class (the InternalRel of A, x))) by XCMPLX_1:120
    .= card (Class (the InternalRel of A, x))/ (card Class (the InternalRel
  of A, x)) - (card (X /\ Class (the InternalRel of A, x)) / (card Class (the
  InternalRel of A, x))) by XBOOLE_1:28
    .= 1 - card (X /\ Class (the InternalRel of A, x)) / (card Class (the
  InternalRel of A, x)) by XCMPLX_1:60
    .= 1 - (MemberFunc (X,A).x) by Def9;
  hence thesis;
end;
