reserve T,U for non empty TopSpace;
reserve t for Point of T;
reserve n for Nat;
reserve T for TopStruct;
reserve f for PartFunc of R^1, T;
reserve c for Curve of T;
reserve T for non empty TopStruct;

theorem Th46:
  n >= 2 implies TUnitSphere(n) is having_trivial_Fundamental_Group
  proof
    assume
A1: n >= 2;
    set T = TUnitSphere(n);
    for t being Point of T, f being Loop of t holds f is nullhomotopic
    proof
      let t be Point of T, f be Loop of t;
      per cases;
      suppose rng f <> the carrier of TUnitSphere(n);
        hence f is nullhomotopic by Lm3;
      end;
      suppose rng f = the carrier of TUnitSphere(n);
        then consider g be Loop of t such that
        A2: g, f are_homotopic and
        A3: rng g <> the carrier of TUnitSphere(n) by A1,Lm4;
        g is nullhomotopic by A3,Lm3;
        then consider C be constant Loop of t such that
        A4: g, C are_homotopic;
        f, C are_homotopic by A2,A4,BORSUK_6:79;
        hence f is nullhomotopic;
      end;
    end;
    hence thesis by Th17;
  end;
