
theorem Th46:
  for W being with_non-empty_element set
  for a, b being Object of W-SUP(SO)_category for f being set
  holds f in <^a,b^> iff
  ex g being sups-preserving Function of latt a, latt b st g = f &
  UpperAdj g is directed-sups-preserving
proof
  let W be with_non-empty_element set;
  let a,b be Object of W-SUP(SO)_category, f be set;
  the carrier of W-SUP(SO)_category c= the carrier of W-SUP_category by
ALTCAT_2:def 11;
  then reconsider a1 = a, b1 = b as Object of W-SUP_category;
  hereby
    assume
A1: f in <^a,b^>;
A2: <^a,b^> c= <^a1,b1^> by ALTCAT_2:31;
    then reconsider g = f as Morphism of a1,b1 by A1;
A3: f = @g by A1,A2,YELLOW21:def 7;
A4: UpperAdj @g is directed-sups-preserving by A1,A2,Def11;
    f is sups-preserving Function of latt a1, latt b1 by A1,A2,Th16;
    hence ex g being sups-preserving Function of latt a, latt b st g = f &
    UpperAdj g is directed-sups-preserving by A3,A4;
  end;
  given g being sups-preserving Function of latt a, latt b such that
A5: g = f and
A6: UpperAdj g is directed-sups-preserving;
A7: f in <^a1,b1^> by A5,Th16;
  reconsider g = f as Morphism of a1,b1 by A5,Th16;
  f = @g by A7,YELLOW21:def 7;
  hence thesis by A5,A6,A7,Def11;
end;
