reserve a,b,c,d,x,y,z for object, X,Y,Z for set;
reserve R,S,T for Relation;
reserve F,G for Function;

theorem Th46:
  R is well-ordering implies for a st a in field R holds
  not R,R |_2 (R-Seg(a)) are_isomorphic
proof
  assume
A1: R is well-ordering;
  let a such that
A2: a in field R;
  set S = R |_2 (R-Seg(a));
  set F = canonical_isomorphism_of(R,S);
  assume R,R |_2 (R-Seg(a)) are_isomorphic;
  then
A3: F is_isomorphism_of R,S by A1,Def9;
  then
A4: dom F = field R;
A5: F is one-to-one by A3;
A6: now
    let b,c;
    assume that
A7: [b,c] in R and
A8: b <> c;
    [F.b,F.c] in R |_2 (R-Seg(a)) by A3,A7;
    hence [F.b,F.c] in R by XBOOLE_0:def 4;
    b in field R & c in field R by A7,RELAT_1:15;
    hence F.b <> F.c by A4,A5,A8;
  end;
A9: rng F = field S by A3;
  field S = R-Seg(a) by A1,Th32;
  then F.a in R-Seg(a) by A2,A4,A9,FUNCT_1:def 3;
  then
A10: [F.a,a] in R & F.a <> a by Th1;
  rng F c= field R by A9,Th13;
  then [a,F.a] in R by A1,A2,A4,A6,Th35;
  hence contradiction by A1,A10,Lm3;
end;
