reserve X for BCK-algebra;
reserve x,y for Element of X;
reserve IT for non empty Subset of X;

theorem Th47:
  for X being bounded commutative BCK-algebra,a being Element of X
st a is being_greatest holds (X is BCK-implicative iff for x,y being Element of
  X holds y\(y\x) = x\(a\y) )
proof
  let X be bounded commutative BCK-algebra;
  let a be Element of X;
  assume
A1: a is being_greatest;
  thus X is BCK-implicative implies for x,y being Element of X holds y\(y\x) =
  x\(a\y)
  proof
    assume
A2: X is BCK-implicative;
    let x,y be Element of X;
    y\(y\x) = x\(x\y) by Def1
      .= x\((a\y)\((a\y)\x)) by A1,A2,Th46
      .= x\(x\(x\(a\y))) by Def1;
    hence thesis by BCIALG_1:8;
  end;
  assume
A3: for x,y being Element of X holds y\(y\x) = x\(a\y);
  for x,y being Element of X holds (a\y)\((a\y)\x) = x\y
  proof
    let x,y be Element of X;
    (a\y)\((a\y)\x) = x\(a\(a\y)) by A3
      .= x\(y\(y\a)) by Def1
      .= x\(y\0.X) by A1;
    hence thesis by BCIALG_1:2;
  end;
  hence thesis by A1,Th46;
end;
