
theorem Th47:
  for f be without-infty Function of [:NAT,NAT:],ExtREAL,
      n,m be Nat holds
   (Partial_Sums f).(n+1,m)
     = (Partial_Sums_in_cod2 f).(n+1,m) + (Partial_Sums f).(n,m) &
   (Partial_Sums_in_cod1(Partial_Sums_in_cod2 f)).(n,m+1)
     = (Partial_Sums_in_cod1 f).(n,m+1)
       + (Partial_Sums_in_cod1(Partial_Sums_in_cod2 f)).(n,m)
proof
   let f be without-infty Function of [:NAT,NAT:],ExtREAL;
   let n,m be Nat;
   set RPS = Partial_Sums f;
   set CPS = Partial_Sums_in_cod1(Partial_Sums_in_cod2 f);
   set ROW = Partial_Sums_in_cod1 f;
   set COL = Partial_Sums_in_cod2 f;
   defpred P[Nat] means RPS.(n+1,$1) = COL.(n+1,$1) + RPS.(n,$1);
a1:RPS.(n,0) = ROW.(n,0) by DefCSM;
   RPS.(n+1,0) = ROW.(n+1,0) by DefCSM
    .= ROW.(n,0) + f.(n+1,0) by DefRSM; then
a3:P[0] by a1,DefCSM;
a4:for k be Nat st P[k] holds P[k+1]
   proof
    let k be Nat;
    assume A5: P[k];
a6: COL.(n+1,k+1) = COL.(n+1,k) + f.(n+1,k+1) by DefCSM;
X1: COL.(n+1,k) <> -infty & f.(n+1,k+1) <> -infty & RPS.(n,k) <> -infty
  & ROW.(n,k+1) <> -infty & RPS.(n+1,k) <> -infty by MESFUNC5:def 5; then
X2: COL.(n+1,k) + f.(n+1,k+1) <> -infty by XXREAL_3:17;
    RPS.(n,k+1) = RPS.(n,k) + ROW.(n,k+1) by DefCSM; then
    COL.(n+1,k+1) + RPS.(n,k+1)
      = COL.(n+1,k) + f.(n+1,k+1) + RPS.(n,k) + ROW.(n,k+1)
         by a6,X1,X2,XXREAL_3:29
     .= COL.(n+1,k) + RPS.(n,k) + f.(n+1,k+1) + ROW.(n,k+1)
         by X1,XXREAL_3:29
     .= RPS.(n+1,k) + ( f.(n+1,k+1) + ROW.(n,k+1) ) by A5,X1,XXREAL_3:29
     .= RPS.(n+1,k) + ROW.(n+1,k+1) by DefRSM;
    hence P[k+1] by DefCSM;
   end;
   for k be Nat holds P[k] from NAT_1:sch 2(a3,a4);
   hence RPS.(n+1,m) = COL.(n+1,m) + RPS.(n,m);
   defpred Q[Nat] means CPS.($1,m+1) = ROW.($1,m+1) + CPS.($1,m);
b1:CPS.(0,m) = COL.(0,m) by DefRSM;
   CPS.(0,m+1) = COL.(0,m+1) by DefRSM
    .= COL.(0,m) + f.(0,m+1) by DefCSM; then
b3:Q[0] by b1,DefRSM;
b4:for k be Nat st Q[k] holds Q[k+1]
   proof
    let k be Nat;
    assume B5: Q[k];
b6: ROW.(k+1,m+1) = ROW.(k,m+1) + f.(k+1,m+1) by DefRSM;
X3: ROW.(k,m+1) <> -infty & f.(k+1,m+1) <> -infty & CPS.(k,m) <> -infty
  & COL.(k+1,m) <> -infty & CPS.(k,m+1) <> -infty by MESFUNC5:def 5; then
X4: ROW.(k,m+1) + f.(k+1,m+1) <> -infty by XXREAL_3:17;
    CPS.(k+1,m) = CPS.(k,m) + COL.(k+1,m) by DefRSM; then
    ROW.(k+1,m+1) + CPS.(k+1,m)
     = ROW.(k,m+1) + f.(k+1,m+1) + CPS.(k,m) + COL.(k+1,m)
         by b6,X3,X4,XXREAL_3:29
    .= ROW.(k,m+1) + CPS.(k,m) + f.(k+1,m+1) + COL.(k+1,m)
         by X3,XXREAL_3:29
    .= CPS.(k,m+1) + ( f.(k+1,m+1) + COL.(k+1,m) ) by B5,X3,XXREAL_3:29
     .= CPS.(k,m+1) + COL.(k+1,m+1) by DefCSM;
    hence Q[k+1] by DefRSM;
   end;
   for k be Nat holds Q[k] from NAT_1:sch 2(b3,b4);
   hence thesis;
end;
