reserve x for set;
reserve i,j for Integer;
reserve n,n1,n2,n3 for Nat;
reserve p for Prime;
reserve a,b,c,d for Element of GF(p);
reserve K for Ring;
reserve a1,a2,a3,a4,a5,a6 for Element of K;
reserve px,py,pz for object;
reserve Px,Py,Pz for Element of GF(p);
reserve P for Element of ProjCo(GF(p));
reserve O for Element of EC_SetProjCo(a,b,p);

theorem Th47:
  for p be 5_or_greater Prime, z be Element of EC_WParam p,
  P, Q be Element of EC_SetProjCo(z`1,z`2,p)
  holds P _EQ_ compell_ProjCo(z,p).Q iff compell_ProjCo(z,p).P _EQ_ Q
  proof
    let p be 5_or_greater Prime, z be Element of EC_WParam p,
    P, Q be Element of EC_SetProjCo(z`1,z`2,p);
    set a = z`1;
    set b = z`2;
    set CP = compell_ProjCo(z,p).P;
    reconsider CP as Element of EC_SetProjCo(a,b,p);
    set CQ = compell_ProjCo(z,p).Q;
    reconsider CQ as Element of EC_SetProjCo(a,b,p);
    hereby
      assume A1: P _EQ_ compell_ProjCo(z,p).Q;
      compell_ProjCo(z,p).P _EQ_ compell_ProjCo(z,p).CQ by A1,Th46;
      hence compell_ProjCo(z,p).P _EQ_ Q by Th41;
    end;
    assume A2: compell_ProjCo(z,p).P _EQ_ Q;
    compell_ProjCo(z,p).CP _EQ_ compell_ProjCo(z,p).Q by A2,Th46;
    hence P _EQ_ compell_ProjCo(z,p).Q by Th41;
  end;
