reserve E, x, y, X for set;
reserve A, B, C for Subset of E^omega;
reserve a, a1, a2, b for Element of E^omega;
reserve i, k, l, m, n for Nat;

theorem Th47:
  A c= B |^.. k implies B |^.. k = (B \/ A) |^.. k
proof
  defpred P[Nat] means $1 >= k implies (B \/ A) |^ $1 c= B |^.. k;
  B |^ 1 c= B |^.. 1 by Th3;
  then
A1: B c= B |^.. 1 by FLANG_1:25;
  assume
A2: A c= B |^.. k;
A3: now
    let n;
    assume
A4: P[n];
    now
      assume
A5:   n + 1 >= k;
      per cases by A5,NAT_1:8;
      suppose
A6:     n + 1 = k;
        per cases;
        suppose
          k = 0;
          hence (B \/ A) |^ (n + 1) c= B |^.. k by A6;
        end;
        suppose
A7:       k > 0;
          then k >= 0 + 1 by NAT_1:13;
          then B |^.. k c= B |^.. 1 by Th5;
          then A c= B |^.. 1 by A2;
          then B \/ A c= B |^.. 1 by A1,XBOOLE_1:8;
          then
A8:       (B \/ A) |^ k c= (B |^.. 1) |^ k by FLANG_1:37;
          (B |^.. 1) |^ k c= B |^.. (1 * k) by A7,Th19;
          hence (B \/ A) |^ (n + 1) c= B |^.. k by A6,A8;
        end;
      end;
      suppose
A9:     n >= k;
A10:    B |^.. (k + k) c= B |^.. k by Th5,NAT_1:11;
        (B \/ A) |^ n ^^ A c= B |^.. (k + k) by A2,A4,A9,Th21;
        then
A11:    (B \/ A) |^ n ^^ A c= B |^.. k by A10;
A12:    B |^.. (k + 1) c= B |^.. k by Th5,NAT_1:11;
        (B \/ A) |^ n ^^ B c= B |^.. (k + 1) by A1,A4,A9,Th21;
        then
A13:    (B \/ A) |^ n ^^ B c= B |^.. k by A12;
        (B \/ A) |^ (n + 1) = (B \/ A) |^ n ^^ (B \/ A) by FLANG_1:23
          .= (B \/ A) |^ n ^^ B \/ (B \/ A) |^ n ^^ A by FLANG_1:20;
        hence (B \/ A) |^ (n + 1) c= B |^.. k by A13,A11,XBOOLE_1:8;
      end;
    end;
    hence P[n + 1];
  end;
A14: P[0]
  proof
    assume 0 >= k;
    then k = 0;
    then
A15: B |^.. k = B* by Th11;
A16: <%>E in B* by FLANG_1:48;
    (B \/ A) |^ 0 = {<%>E} by FLANG_1:24;
    hence thesis by A15,A16,ZFMISC_1:31;
  end;
A17: for n holds P[n] from NAT_1:sch 2(A14, A3);
A18: (B \/ A) |^.. k c= B |^.. k
  proof
    let x be object;
    assume x in (B \/ A) |^.. k;
    then consider n such that
A19: n >= k and
A20: x in (B \/ A) |^ n by Th2;
    (B \/ A) |^ n c= B |^.. k by A17,A19;
    hence thesis by A20;
  end;
  B |^.. k c= (B \/ A) |^.. k by Th13,XBOOLE_1:7;
  hence thesis by A18,XBOOLE_0:def 10;
end;
