
theorem Th47:
  for G1, G2 being _Graph, F being PGraphMapping of G1, G2
  for X being Subset of the_Vertices_of G1 st F is weak_SG-embedding
  holds card G1.edgesBetween(X) c= card G2.edgesBetween(F_V.:X)
proof
  let G1, G2 be _Graph, F be PGraphMapping of G1, G2;
  let X be Subset of the_Vertices_of G1;
  assume A1: F is weak_SG-embedding;
  set f = F_E | G1.edgesBetween(X);
  A2: dom f = dom F_E /\ G1.edgesBetween(X) by RELAT_1:61
    .= the_Edges_of G1 /\ G1.edgesBetween(X) by A1, Def11
    .= G1.edgesBetween(X) by XBOOLE_1:28;
  for y being object holds y in rng f implies
    y in G2.edgesBetween(F_V.:X)
  proof
    let y be object;
    assume y in rng f;
    then consider x being object such that
      A3: x in dom f & f.x = y by FUNCT_1:def 3;
    set v = (the_Source_of G1).x, w = (the_Target_of G1).x;
    A4: x in the_Edges_of G1 & v in X & w in X by A2, A3, GLIB_000:31;
    then v in the_Vertices_of G1 & w in the_Vertices_of G1;
    then A5: v in dom F_V & w in dom F_V by A1, Def11;
    A6: x in dom F_E by A1, A4, Def11;
    x Joins v,w,G1 by A4, GLIB_000:def 13;
    then F_E.x Joins F_V.v,F_V.w,G2 by A5, A6, Th4;
    then A7: y Joins F_V.v,F_V.w,G2 by A3, FUNCT_1:47;
    F_V.v in F_V.:X & F_V.w in F_V.:X by A4, A5, FUNCT_1:def 6;
    hence thesis by A7, GLIB_000:32;
  end;
  then A8: rng f c= G2.edgesBetween(F_V.:X) by TARSKI:def 3;
  f is one-to-one by A1, FUNCT_1:52;
  hence thesis by A2, A8, CARD_1:10;
end;
