reserve n for Nat,
  i,j for Nat,
  r,s,r1,s1,r2,s2,r9,s9 for Real,
  p,q for Point of TOP-REAL 2,
  G for Go-board,
  x,y for set,
  v for Point of Euclid 2;

theorem Th47:
  1 <= i & i < len G implies LSeg(1/2*(G*(i,width G)+G*(i+1,width
G))+ |[0,1]|, 1/2*(G*(i,width G)+G*(i+1,width G))) c= Int cell(G,i,width G) \/
  { 1/2*(G*(i,width G)+G*(i+1,width G)) }
proof
  assume that
A1: 1 <= i and
A2: i < len G;
  let x be object;
  assume
A3: x in LSeg(1/2*(G*(i,width G)+G*(i+1,width G))+|[0,1]|, 1/2*(G*(i,
  width G)+G*(i+1,width G)));
  then reconsider p = x as Point of TOP-REAL 2;
  consider r such that
A4: p = (1-r)*(1/2*(G*(i,width G)+G*(i+1,width G))+|[0,1]|) +r*(1/2*(G*(
  i,width G)+G*(i+1,width G))) and
A5: 0<=r and
A6: r<=1 by A3;
  now
    per cases by A6,XXREAL_0:1;
    case
      r = 1;
      then p = 0.TOP-REAL 2 + 1*(1/2*(G*(i,width G)+G*(i+1,width G))) by A4,
RLVECT_1:10
        .= 1*(1/2*(G*(i,width G)+G*(i+1,width G))) by RLVECT_1:4
        .= 1/2*(G*(i,width G)+G*(i+1,width G)) by RLVECT_1:def 8;
      hence p in { 1/2*(G*(i,width G)+G*(i+1,width G)) } by TARSKI:def 1;
    end;
    case
A7:   r < 1;
      set r3 = (1-r)*(1/2), s3 = r*(1/2);
      set s2 = G*(1,width G)`2, r1 = G*(i,1)`1, r2 = G*(i+1,1)`1;
A8:   r3*(r1+r1)+s3*(r1+r1) = r1;
A9:   i+1 <= len G by A2,NAT_1:13;
      0 <> width G by MATRIX_0:def 10;
      then
A10:  1 <= width G by NAT_1:14;
      i < i+1 by XREAL_1:29;
      then
A11:  r1 < r2 by A1,A9,A10,GOBOARD5:3;
      then
A12:  r1+r1 < r1+r2 by XREAL_1:6;
      then
A13:  s3*(r1+r1) <= s3*(r1+r2) by A5,XREAL_1:64;
A14:  1 - r > 0 by A7,XREAL_1:50;
      then
A15:  r3 > (1/2)*0 by XREAL_1:68;
      then r3*(r1+r1) < r3*(r1+r2) by A12,XREAL_1:68;
      then
A16:  r1 < r3*(r1+r2)+s3*(r1+r2) by A13,A8,XREAL_1:8;
A17:  s2+(1-r) > s2 by A14,XREAL_1:29;
A18:  1 <= i+1 by A1,NAT_1:13;
A19:  r1+r2 < r2+r2 by A11,XREAL_1:6;
      then
A20:  s3*(r1+r2) <= s3*(r2+r2) by A5,XREAL_1:64;
A21:  Int cell(G,i,width G) = { |[r9,s9]| : G*(i,1)`1 < r9 & r9 < G*(i+1,
      1)`1 & G* (1,width G)`2 < s9 } by A1,A2,Th25;
A22:  r3*(r2+r2)+s3*(r2+r2) = r2;
      r3*(r1+r2) < r3*(r2+r2) by A15,A19,XREAL_1:68;
      then
A23:  r3*(r1+r2)+s3*(r1+r2) < r2 by A20,A22,XREAL_1:8;
A24:  G*(i,width G) = |[G*(i,width G)`1,G*(i,width G)`2]| by EUCLID:53
        .= |[G*(i,width G)`1,s2]| by A1,A2,A10,GOBOARD5:1
        .= |[r1,s2]| by A1,A2,A10,GOBOARD5:2;
A25:  G*(i+1,width G) = |[G*(i+1,width G)`1,G*(i+1,width G)`2]| by EUCLID:53
        .= |[G*(i+1,width G)`1,s2]| by A18,A9,A10,GOBOARD5:1
        .= |[r2,s2]| by A18,A9,A10,GOBOARD5:2;
      p = (1-r)*(1/2*(G*(i,width G)+G*(i+1,width G)))+(1-r)*|[0,1]| +r*(1
      /2*(G*(i,width G)+G* (i+1,width G))) by A4,RLVECT_1:def 5
        .= r3*(G*(i,width G)+G*(i+1,width G))+(1-r)*|[0,1]|+ r*(1/2*(G*(i,
      width G)+G*(i+1,width G))) by RLVECT_1:def 7
        .= r3*(G*(i,width G)+G*(i+1,width G))+|[(1-r)*0,(1-r)*1]|+ r*(1/2*(G
      *(i,width G)+G*(i+1,width G))) by EUCLID:58
        .= r3*(G*(i,width G)+G*(i+1,width G))+|[0,1-r]|+ s3*(G*(i,width G)+G
      *(i+1,width G)) by RLVECT_1:def 7
        .= r3*|[r1+r2,s2+s2]|+|[0,1-r]|+s3*(G*(i,width G)+G*(i+1,width G))
      by A25,A24,EUCLID:56
        .= r3*|[r1+r2,s2+s2]|+|[0,1-r]|+s3*|[r1+r2,s2+s2]| by A25,A24,EUCLID:56
        .= |[r3*(r1+r2),r3*(s2+s2)]|+|[0,1-r]|+s3*|[r1+r2,s2+s2]| by EUCLID:58
        .= |[r3*(r1+r2),r3*(s2+s2)]|+|[0,1-r]|+|[s3*(r1+r2),s3*(s2+s2)]| by
EUCLID:58
        .= |[r3*(r1+r2)+0,r3*(s2+s2)+(1-r)]|+|[s3*(r1+r2),s3*(s2+s2)]| by
EUCLID:56
        .= |[r3*(r1+r2)+s3*(r1+r2),r3*(s2+s2)+(1-r)+s3*(s2+s2)]| by EUCLID:56;
      hence p in Int cell(G,i,width G) by A17,A16,A23,A21;
    end;
  end;
  hence thesis by XBOOLE_0:def 3;
end;
