reserve r,x,x0,a,b for Real;
reserve n,m for Element of NAT;
reserve A for non empty closed_interval Subset of REAL;
reserve Z for open Subset of REAL;
reserve f, f1, f2, f3 for PartFunc of REAL, REAL;

theorem
  A c= Z & Z c= ]. -1,1 .[ & (for x st x in Z holds f.x=-1/(1+x^2)) & Z
  = dom f & f|A is continuous implies integral(f,A) = arccot.(upper_bound A)
   - arccot.(
  lower_bound A)
proof
  assume that
A1: A c= Z and
A2: Z c= ]. -1,1 .[ and
A3: for x st x in Z holds f.x=-1/(1+x^2) and
A4: Z = dom f and
A5: f|A is continuous;
A6: arccot is_differentiable_on Z by A2,SIN_COS9:82;
A7: for x being Element of REAL
st x in dom ((arccot)`|Z) holds ((arccot)`|Z).x = f.x
  proof
    let x be Element of REAL;
    assume x in dom ((arccot)`|Z);
    then
A8: x in Z by A6,FDIFF_1:def 7;
    then ((arccot)`|Z).x = -1/(1+x^2) by A2,SIN_COS9:82
      .= f.x by A3,A8;
    hence thesis;
  end;
  dom ((arccot)`|Z) = dom f by A4,A6,FDIFF_1:def 7;
  then
A9: ((arccot)`|Z) = f by A7,PARTFUN1:5;
  f is_integrable_on A & f|A is bounded by A1,A4,A5,INTEGRA5:10,11;
  hence thesis by A1,A2,A9,INTEGRA5:13,SIN_COS9:82;
end;
