reserve x,y for set;
reserve G for Graph;
reserve vs,vs9 for FinSequence of the carrier of G;
reserve IT for oriented Chain of G;
reserve N for Nat;
reserve n,m,k,i,j for Nat;
reserve r,r1,r2 for Real;
reserve X for non empty set;
reserve p,p1,p2 for Point of TOP-REAL N;
reserve M for non empty MetrSpace;
reserve X,Y for non empty TopSpace;

theorem
  for f,g being Function of I[01],TOP-REAL 2,a,b,c,d being Real ,
  O,I being Point of I[01] st O=0 & I=1 & f is continuous one-to-one & g is
continuous one-to-one & (f.O)`1=a & (f.I)`1=b & (g.O)`2=c & (g.I)`2=d & (for r
being Point of I[01] holds a <=(f.r)`1 & (f.r)`1<=b & a <=(g.r)`1 & (g.r)`1<=b
& c <=(f.r)`2 & (f.r)`2<=d & c <=(g.r)`2 & (g.r)`2<=d) holds rng f meets rng g
proof
  let f,g be Function of I[01],TOP-REAL 2,a,b,c,d be Real, O,I be Point
  of I[01];
  assume that
A1: O=0 & I=1 and
A2: f is continuous one-to-one and
A3: g is continuous one-to-one and
A4: (f.O)`1=a and
A5: (f.I)`1=b and
A6: (g.O)`2=c and
A7: (g.I)`2=d and
A8: for r being Point of I[01] holds a<=(f.r)`1 & (f.r)`1<=b & a<=(g.r)
  `1 & (g.r)`1<=b & c <=(f.r)`2 & (f.r)`2<=d & c <=(g.r)`2 & (g.r)`2<=d;
  reconsider P=rng f as non empty Subset of TOP-REAL 2;
A9: I[01] is compact by HEINE:4,TOPMETR:20;
  then consider f1 being Function of I[01],((TOP-REAL 2) |P) such that
A10: f=f1 and
A11: f1 is being_homeomorphism by A2,Th45;
  reconsider Q=rng g as non empty Subset of TOP-REAL 2;
  consider g1 being Function of I[01],((TOP-REAL 2) |Q) such that
A12: g=g1 and
A13: g1 is being_homeomorphism by A3,A9,Th45;
  reconsider q2=g1.I as Point of TOP-REAL 2 by A7,A12;
  reconsider q1=g1.O as Point of TOP-REAL 2 by A6,A12;
A14: Q is_an_arc_of q1,q2 by A1,A13,TOPREAL1:def 1;
  reconsider p2=f1.I as Point of TOP-REAL 2 by A5,A10;
  reconsider p1=f1.O as Point of TOP-REAL 2 by A4,A10;
A15: for p being Point of TOP-REAL 2 st p in P holds p1`1<=p`1 & p`1<= p2`1
  proof
    let p be Point of TOP-REAL 2;
    assume p in P;
    then ex x being object st x in dom f1 & p=f1.x by A10,FUNCT_1:def 3;
    hence thesis by A4,A5,A8,A10;
  end;
A16: for p being Point of TOP-REAL 2 st p in Q holds p1`1<=p`1 & p`1<= p2`1
  proof
    let p be Point of TOP-REAL 2;
    assume p in Q;
    then ex x being object st x in dom g1 & p=g1.x by A12,FUNCT_1:def 3;
    hence thesis by A4,A5,A8,A10,A12;
  end;
A17: for p being Point of TOP-REAL 2 st p in Q holds q1`2<=p`2 & p`2<= q2 `2
  proof
    let p be Point of TOP-REAL 2;
    assume p in Q;
    then ex x being object st x in dom g1 & p=g1.x by A12,FUNCT_1:def 3;
    hence thesis by A6,A7,A8,A12;
  end;
A18: for p being Point of TOP-REAL 2 st p in P holds q1`2<=p`2 & p`2<= q2`2
  proof
    let p be Point of TOP-REAL 2;
    assume p in P;
    then ex x being object st x in dom f1 & p=f1.x by A10,FUNCT_1:def 3;
    hence thesis by A6,A7,A8,A10,A12;
  end;
  P is_an_arc_of p1,p2 by A1,A11,TOPREAL1:def 1;
  hence thesis by A14,A15,A16,A18,A17,Th43;
end;
