reserve p,q for Point of TOP-REAL 2;

theorem Th47:
  for p1,p2 being Point of TOP-REAL 2, P being compact non empty
Subset of TOP-REAL 2 st P={p where p is Point of TOP-REAL 2: |.p.|=1} & LE p1,
  p2,P & p1<>p2 & p2`2>=0 holds p1`1<p2`1
proof
  let p1,p2 be Point of TOP-REAL 2, P be compact non empty Subset of TOP-REAL
  2;
  assume that
A1: P={p where p is Point of TOP-REAL 2: |.p.|=1} and
A2: LE p1,p2,P and
A3: p1<>p2 and
A4: p2`2>=0;
A5: P is being_simple_closed_curve by A1,JGRAPH_3:26;
  then
A6: p1 in P by A2,JORDAN7:5;
  set P4=Lower_Arc(P);
A7: Upper_Arc(P)={p where p is Point of TOP-REAL 2:p in P & p`2>=0} by A1,Th34;
A8: Upper_Arc(P) /\ P4={W-min(P),E-max(P)} by A5,JORDAN6:def 9;
A9: p2 in P by A2,A5,JORDAN7:5;
A10: now
A11: now
      assume p2=W-min(P);
      then LE p2,p1,P by A5,A6,JORDAN7:3;
      hence contradiction by A1,A2,A3,JGRAPH_3:26,JORDAN6:57;
    end;
    assume
A12: p2 in Lower_Arc(P);
    p2 in Upper_Arc(P) by A4,A9,A7;
    then p2 in {W-min(P),E-max(P)} by A8,A12,XBOOLE_0:def 4;
    then p2=W-min(P) or p2=E-max(P) by TARSKI:def 2;
    then
A13: p2= |[1,0]| by A1,A11,Th30;
    then
A14: p2`1=1 by EUCLID:52;
A15: ex p8 being Point of TOP-REAL 2 st p8=p1 & |.p8.|=1 by A1,A6;
A16: now
      assume
A17:  p1`1=1;
      1^2=(p1`1)^2+(p1`2)^2 by A15,JGRAPH_3:1;
      then p1`2=0 by A17,XCMPLX_1:6;
      hence contradiction by A3,A13,A17,EUCLID:53;
    end;
    p1`1<=1 by A15,Th1;
    hence thesis by A14,A16,XXREAL_0:1;
  end;
  now
    assume p2=W-min(P);
    then LE p2,p1,P by A5,A6,JORDAN7:3;
    hence contradiction by A1,A2,A3,JGRAPH_3:26,JORDAN6:57;
  end;
  then
A18: p1 in Upper_Arc(P) & p2 in Upper_Arc(P)& not p2=W-min(P) & LE p1,p2,
  Upper_Arc(P),W-min(P),E-max(P) or p1`1<p2`1 by A2,A10;
  consider f being Function of I[01],(TOP-REAL 2)|Upper_Arc(P) such that
A19: f is being_homeomorphism and
A20: for q1,q2 being Point of TOP-REAL 2, r1,r2 being Real st f.r1=q1 &
  f.r2=q2 & r1 in [.0,1.] & r2 in [.0,1.] holds r1<r2 iff q1`1<q2`1 and
A21: f.0=W-min(P) & f.1=E-max(P) by A1,Th43;
A22: rng f=[#]((TOP-REAL 2)|Upper_Arc(P)) by A19,TOPS_2:def 5
    .=Upper_Arc(P) by PRE_TOPC:def 5;
  now
    per cases;
    case
A23:  not p1`1 < p2`1;
      then consider x1 being object such that
A24:  x1 in dom f and
A25:  p1=f.x1 by A18,A22,FUNCT_1:def 3;
      consider x2 being object such that
A26:  x2 in dom f and
A27:  p2=f.x2 by A18,A22,A23,FUNCT_1:def 3;
A28:  dom f=[#](I[01]) by A19,TOPS_2:def 5
        .=[.0,1.] by BORSUK_1:40;
      reconsider r22=x2 as Real by A26;
A29:  0<=r22 & r22<=1 by A26,A28,XXREAL_1:1;
      reconsider r11=x1 as Real by A24;
A30:  r11<r22 iff p1`1<p2`1 by A20,A24,A25,A26,A27,A28;
      r11<=1 by A24,A28,XXREAL_1:1;
      then r11<=r22 or p1`1<p2`1 by A18,A19,A21,A25,A27,A29,JORDAN5C:def 3;
      hence thesis by A3,A25,A27,A30,XXREAL_0:1;
    end;
    case
      p1`1<p2`1;
      hence thesis;
    end;
  end;
  hence thesis;
end;
