reserve n for Nat;

theorem
  for C be compact connected non vertical non horizontal Subset of
  TOP-REAL 2 for p be Point of TOP-REAL 2 holds p in L~Lower_Seq(C,n) & p`1 =
  W-bound L~Cage(C,n) implies p = W-min L~Cage(C,n)
proof
  let C be compact connected non vertical non horizontal Subset of TOP-REAL 2;
  let p be Point of TOP-REAL 2;
  set Ca = Cage(C,n);
  set LS = Lower_Seq(C,n);
  set US = Upper_Seq(C,n);
  set Emax = E-max L~Ca;
  set Nmin = N-min L~Ca;
  set Nmax = N-max L~Ca;
  set Wmax = W-max L~Ca;
  set Wmin = W-min L~Ca;
  set Ebo = E-bound L~Cage(C,n);
  set Sbo = S-bound L~Cage(C,n);
  set Wbo = W-bound L~Cage(C,n);
  set Nbo = N-bound L~Cage(C,n);
  set SW = SW-corner L~Ca;
  assume that
A1: p in L~Lower_Seq(C,n) and
A2: p`1 = W-bound L~Cage(C,n) and
A3: p <> W-min L~Cage(C,n);
A4: LS/.1 = Emax by JORDAN1F:6;
  1 in dom LS by FINSEQ_5:6;
  then
A5: LS.1 = Emax by A4,PARTFUN1:def 6;
  Ebo <> Wbo by SPRECT_1:31;
  then p <> LS.1 by A2,A5,EUCLID:52;
  then reconsider
  g1 = R_Cut(LS,p) as being_S-Seq FinSequence of TOP-REAL 2 by A1,JORDAN3:35;
  len g1 in dom g1 by FINSEQ_5:6;
  then
A6: g1/.len g1 = g1.len g1 by PARTFUN1:def 6
    .= p by A1,JORDAN3:24;
  reconsider g = Rev g1 as being_S-Seq FinSequence of TOP-REAL 2;
  <*p*> is_in_the_area_of Ca by A1,JORDAN1E:18,SPRECT_3:46;
  then g1 is_in_the_area_of Ca by A1,JORDAN1E:18,SPRECT_3:52;
  then
A7: g is_in_the_area_of Ca by SPRECT_3:51;
A8: g/.1 = g1/.len g1 by FINSEQ_5:65;
A9: g/.len g = g/.len g1 by FINSEQ_5:def 3
    .= g1/.1 by FINSEQ_5:65;
  (g1/.1)`1 = (LS/.1)`1 by A1,SPRECT_3:22
    .= Emax`1 by JORDAN1F:6
    .= Ebo by EUCLID:52;
  then
A10: g is_a_h.c._for Ca by A2,A7,A8,A9,A6,SPRECT_2:def 2;
A11: US/.1 = Wmin by JORDAN1F:5;
  1 in dom US by FINSEQ_5:6;
  then
A12: US.1 = Wmin by A11,PARTFUN1:def 6;
A13: L~g = L~g1 by SPPOL_2:22;
  len Cage(C,n) > 4 by GOBOARD7:34;
  then
A14: rng Cage(C,n) c= L~Cage(C,n) by SPPOL_2:18,XXREAL_0:2;
  now
    per cases;
    suppose
A15:  Wmin <> SW;
A16:  not SW in rng Cage(C,n)
      proof
A17:    SW`1 = W-bound L~Cage(C,n) by EUCLID:52;
A18:    SW`2 = S-bound L~Cage(C,n) by EUCLID:52;
        then SW`2 <= N-bound L~Cage(C,n) by SPRECT_1:22;
        then SW in { p1 where p1 is Point of TOP-REAL 2 : p1`1 = W-bound L~
Cage(C,n) & p1`2 <= N-bound L~Cage(C,n) & p1`2 >= S-bound L~Cage(C,n) } by A17
,A18;
        then
A19:    SW in LSeg(SW-corner L~Cage(C,n), NW-corner L~Cage(C,n)) by SPRECT_1:26
;
        assume SW in rng Cage(C,n);
        then SW in LSeg(SW-corner L~Cage(C,n), NW-corner L~Cage(C,n)) /\ L~
        Cage(C,n) by A14,A19,XBOOLE_0:def 4;
        then
A20:    SW`2 >= (W-min L~Cage(C,n))`2 by PSCOMP_1:31;
A21:    (W-min L~Cage(C,n))`1 = SW`1 by PSCOMP_1:29;
        (W-min L~Cage(C,n))`2 >= SW`2 by PSCOMP_1:30;
        then (W-min L~Cage(C,n))`2 = SW`2 by A20,XXREAL_0:1;
        hence contradiction by A15,A21,TOPREAL3:6;
      end;
      Nmin in rng US by Th7;
      then R_Cut(US,Nmin) = mid(US,1,Nmin..US) by JORDAN1G:49;
      then
A22:  rng R_Cut(US,Nmin) c= rng US by FINSEQ_6:119;
      rng US c= rng Ca by JORDAN1G:39;
      then rng R_Cut(US,Nmin) c= rng Ca by A22;
      then not SW in rng R_Cut(US,Nmin) by A16;
      then rng R_Cut(US,Nmin) misses {SW} by ZFMISC_1:50;
      then rng R_Cut(US,Nmin) misses rng <*SW*> by FINSEQ_1:38;
      then
A23:  rng Rev R_Cut(US,Nmin) misses rng <*SW*> by FINSEQ_5:57;
      set h1 = Rev R_Cut(US,Nmin)^<*SW*>;
A24:  <*SW*> is one-to-one by FINSEQ_3:93;
      Wmax in L~Ca by SPRECT_1:13;
      then
A25:  Nbo >= Wmax`2 by PSCOMP_1:24;
A26:  Nmin in L~US by Th7;
      then <*Nmin*> is_in_the_area_of Ca by JORDAN1E:17,SPRECT_3:46;
      then R_Cut(US,Nmin) is_in_the_area_of Ca by A26,JORDAN1E:17,SPRECT_3:52;
      then
A27:  Rev R_Cut(US,Nmin) is_in_the_area_of Ca by SPRECT_3:51;
      Wmax`2 > Wmin`2 by SPRECT_2:57;
      then
A28:  Nmin <> US.1 by A12,A25,EUCLID:52;
      then reconsider RCutUS = R_Cut(US,Nmin) as being_S-Seq FinSequence of
      TOP-REAL 2 by A26,JORDAN3:35;
A29:  Rev RCutUS/.len Rev RCutUS = Rev RCutUS/.len RCutUS by FINSEQ_5:def 3
        .= RCutUS/.1 by FINSEQ_5:65
        .= US/.1 by A26,SPRECT_3:22
        .= Wmin by JORDAN1F:5;
      then (Rev RCutUS/.len Rev RCutUS)`1 = W-bound L~Ca by EUCLID:52
        .= SW`1 by EUCLID:52
        .= (<*SW*>/.1)`1 by FINSEQ_4:16;
      then reconsider
      h1 as one-to-one special FinSequence of TOP-REAL 2 by A23,A24,FINSEQ_3:91
,GOBOARD2:8;
      set h = Rev h1;
A30:  h is special by SPPOL_2:40;
      <*SW*> is_in_the_area_of Ca by SPRECT_2:28;
      then h1 is_in_the_area_of Ca by A27,SPRECT_2:24;
      then
A31:  h is_in_the_area_of Ca by SPRECT_3:51;
      L~h = L~h1 by SPPOL_2:22;
      then
A32:  L~h = L~Rev RCutUS \/ LSeg(Rev RCutUS/.len Rev RCutUS,SW) by SPPOL_2:19;
A33:  Index(Nmin,US)+1 >= 0+1 by XREAL_1:7;
A34:  2 <= len g by TOPREAL1:def 8;
      len h1 = len Rev R_Cut(US,Nmin) + 1 by FINSEQ_2:16
        .= len R_Cut(US,Nmin) + 1 by FINSEQ_5:def 3
        .= Index(Nmin,US)+1+1 by A26,A28,JORDAN3:25;
      then len h1 >= 1+1 by A33,XREAL_1:7;
      then
A35:  len h >= 2 by FINSEQ_5:def 3;
A36:  h/.1 = h1/.len h1 by FINSEQ_5:65;
A37:  len US in dom US by FINSEQ_5:6;
      1 in dom Rev RCutUS by FINSEQ_5:6;
      then h1/.1 = Rev RCutUS/.1 by FINSEQ_4:68
        .= R_Cut(US,Nmin)/.len R_Cut(US,Nmin) by FINSEQ_5:65
        .= Nmin by A26,Th45;
      then
A38:  (h1/.1)`2 = Nbo by EUCLID:52;
A39:  (h1/.len h1)`2 = (h1/.(len Rev R_Cut(US,Nmin)+1))`2 by FINSEQ_2:16
        .= SW`2 by FINSEQ_4:67
        .= Sbo by EUCLID:52;
A40:  len LS in dom LS by FINSEQ_5:6;
      h/.len h = h/.len h1 by FINSEQ_5:def 3
        .= h1/.1 by FINSEQ_5:65;
      then h is_a_v.c._for Ca by A31,A38,A36,A39,SPRECT_2:def 3;
      then L~g meets L~h by A10,A30,A34,A35,SPRECT_2:29;
      then consider x be object such that
A41:  x in L~g and
A42:  x in L~h by XBOOLE_0:3;
      reconsider x as Point of TOP-REAL 2 by A41;
A43:  L~RCutUS c= L~US by Th7,JORDAN3:41;
A44:  L~g c= L~LS by A1,A13,JORDAN3:41;
      then
A45:  x in L~LS by A41;
      now
        per cases by A42,A32,XBOOLE_0:def 3;
        suppose
          x in L~Rev RCutUS;
          then
A46:      x in L~RCutUS by SPPOL_2:22;
          then x in L~LS /\ L~US by A41,A44,A43,XBOOLE_0:def 4;
          then
A47:      x in {Emax,Wmin} by JORDAN1E:16;
          now
            per cases by A47,TARSKI:def 2;
            suppose
              x = Emax;
              then US/.len US in L~R_Cut(US,Nmin) by A46,JORDAN1F:7;
              then US.len US in L~R_Cut(US,Nmin) by A37,PARTFUN1:def 6;
              then US.len US = Nmin by A26,Th43;
              then US/.len US = Nmin by A37,PARTFUN1:def 6;
              then
A48:          Emax = Nmin by JORDAN1F:7;
              Nmax in L~Ca by SPRECT_1:11;
              then
A49:          Ebo >= Nmax`1 by PSCOMP_1:24;
              Nmax`1 > Nmin`1 by SPRECT_2:51;
              hence contradiction by A48,A49,EUCLID:52;
            end;
            suppose
              x = Wmin;
              then LS/.len LS in L~R_Cut(LS,p) by A13,A41,JORDAN1F:8;
              then LS.len LS in L~R_Cut(LS,p) by A40,PARTFUN1:def 6;
              then LS.len LS = p by A1,Th43;
              then LS/.len LS = p by A40,PARTFUN1:def 6;
              hence contradiction by A3,JORDAN1F:8;
            end;
          end;
          hence contradiction;
        end;
        suppose
A50:      x in LSeg(Rev RCutUS/.len Rev RCutUS,SW);
          Wmin`2 >= SW`2 by PSCOMP_1:30;
          then
A51:      Wmin`2 >= x`2 by A29,A50,TOPREAL1:4;
A52:      Wmin`1 = Wbo by EUCLID:52;
          SW`1 = Wbo by EUCLID:52;
          then
A53:      x`1 = Wbo by A29,A50,A52,GOBOARD7:5;
          L~Ca = L~LS \/ L~US by JORDAN1E:13;
          then L~LS c= L~Ca by XBOOLE_1:7;
          then x in W-most L~Ca by A45,A53,SPRECT_2:12;
          then x`2 >= Wmin`2 by PSCOMP_1:31;
          then x`2 = Wmin`2 by A51,XXREAL_0:1;
          then x = Wmin by A52,A53,TOPREAL3:6;
          then LS/.len LS in L~R_Cut(LS,p) by A13,A41,JORDAN1F:8;
          then LS.len LS in L~R_Cut(LS,p) by A40,PARTFUN1:def 6;
          then LS.len LS = p by A1,Th43;
          then LS/.len LS = p by A40,PARTFUN1:def 6;
          hence contradiction by A3,JORDAN1F:8;
        end;
      end;
      hence contradiction;
    end;
    suppose
A54:  Wmin = SW;
      set h = R_Cut(US,Nmin);
A55:  2 <= len g by TOPREAL1:def 8;
      Wmax in L~Ca by SPRECT_1:13;
      then
A56:  Nbo >= Wmax`2 by PSCOMP_1:24;
A57:  Nmin in L~US by Th7;
      then <*Nmin*> is_in_the_area_of Ca by JORDAN1E:17,SPRECT_3:46;
      then
A58:  R_Cut(US,Nmin) is_in_the_area_of Ca by A57,JORDAN1E:17,SPRECT_3:52;
      Wmax`2 > Wmin`2 by SPRECT_2:57;
      then Nmin <> US.1 by A12,A56,EUCLID:52;
      then reconsider RCutUS = R_Cut(US,Nmin) as being_S-Seq FinSequence of
      TOP-REAL 2 by A57,JORDAN3:35;
A59:  len RCutUS >= 2 by TOPREAL1:def 8;
      R_Cut(US,Nmin)/.len R_Cut(US,Nmin) = Nmin by A57,Th45;
      then
A60:  (h/.len h)`2 = Nbo by EUCLID:52;
      RCutUS/.1 = US/.1 by A57,SPRECT_3:22
        .= Wmin by JORDAN1F:5;
      then (h/.1)`2 = Sbo by A54,EUCLID:52;
      then h is_a_v.c._for Ca by A58,A60,SPRECT_2:def 3;
      then L~g meets L~h by A10,A55,A59,SPRECT_2:29;
      then consider x be object such that
A61:  x in L~g and
A62:  x in L~h by XBOOLE_0:3;
      reconsider x as Point of TOP-REAL 2 by A61;
A63:  len LS in dom LS by FINSEQ_5:6;
A64:  L~g c= L~LS by A1,A13,JORDAN3:41;
A65:  len US in dom US by FINSEQ_5:6;
      L~RCutUS c= L~US by Th7,JORDAN3:41;
      then x in L~LS /\ L~US by A61,A62,A64,XBOOLE_0:def 4;
      then
A66:  x in {Emax,Wmin} by JORDAN1E:16;
      now
        per cases by A66,TARSKI:def 2;
        suppose
          x = Emax;
          then US/.len US in L~R_Cut(US,Nmin) by A62,JORDAN1F:7;
          then US.len US in L~R_Cut(US,Nmin) by A65,PARTFUN1:def 6;
          then US.len US = Nmin by A57,Th43;
          then US/.len US = Nmin by A65,PARTFUN1:def 6;
          then
A67:      Emax = Nmin by JORDAN1F:7;
          Nmax in L~Ca by SPRECT_1:11;
          then
A68:      Ebo >= Nmax`1 by PSCOMP_1:24;
          Nmax`1 > Nmin`1 by SPRECT_2:51;
          hence contradiction by A67,A68,EUCLID:52;
        end;
        suppose
          x = Wmin;
          then LS/.len LS in L~R_Cut(LS,p) by A13,A61,JORDAN1F:8;
          then LS.len LS in L~R_Cut(LS,p) by A63,PARTFUN1:def 6;
          then LS.len LS = p by A1,Th43;
          then LS/.len LS = p by A63,PARTFUN1:def 6;
          hence contradiction by A3,JORDAN1F:8;
        end;
      end;
      hence contradiction;
    end;
  end;
  hence contradiction;
end;
