
theorem Th42:
for X1,X2 be non empty set, S1 be SigmaField of X1, S2 be SigmaField of X2,
 E be Element of sigma(measurable_rectangles(S1,S2)), K be set st
  K = {C where C is Subset of [:X1,X2:] :
          for p be set holds X-section(C,p) in S2}
holds Field_generated_by measurable_rectangles(S1,S2) c= K
  & K is SigmaField of [:X1,X2:]
proof
   let X1,X2 be non empty set, S1 be SigmaField of X1, S2 be SigmaField of X2,
       E be Element of sigma(measurable_rectangles(S1,S2)), K be set;
   assume AS: K = {C where C is Subset of [:X1,X2:] :
                for x be set holds X-section(C,x) in S2};
A1:now let C1,C2 be set;
    assume A2: C1 in K & C2 in K; then
    consider SC1 be Subset of [:X1,X2:] such that
A3:  C1 = SC1 & for x be set holds X-section(SC1,x) in S2 by AS;
    consider SC2 be Subset of [:X1,X2:] such that
A4:  C2 = SC2 & for x be set holds X-section(SC2,x) in S2 by AS,A2;
    now let x be set;
A5:  X-section(SC1,x) in S2 & X-section(SC2,x) in S2 by A3,A4;
     X-section(SC1 \/ SC2,x) = X-section(SC1,x) \/ X-section(SC2,x) by Th20;
     hence X-section(SC1\/SC2,x) in S2 by A5,PROB_1:3;
    end;
    hence C1 \/ C2 in K by AS,A3,A4;
   end; then
A6:K is cup-closed by FINSUB_1:def 1;
   for x be set holds X-section({}[:X1,X2:],x) in S2 by MEASURE1:7;
   then
A7:{} in K by AS;
   now let C be set;
    assume C in DisUnion measurable_rectangles(S1,S2); then
    C in {A where A is Subset of [:X1,X2:] :
           ex F be disjoint_valued FinSequence of measurable_rectangles(S1,S2)
             st A = Union F} by SRINGS_3:def 3; then
    consider C1 be Subset of [:X1,X2:] such that
A8:  C = C1
   & ex F be disjoint_valued FinSequence of measurable_rectangles(S1,S2)
       st C1 = Union F;
    consider F be disjoint_valued FinSequence of measurable_rectangles(S1,S2)
     such that
A9:  C1 = Union F by A8;
    for n be Nat st n in dom F holds F.n in K
    proof
     let n be Nat;
     assume n in dom F; then
     F.n in measurable_rectangles(S1,S2) by PARTFUN1:4; then
     F.n in the set of all [:A,B:] where A is Element of S1, B is Element of S2
      by MEASUR10:def 5; then
     consider A be Element of S1, B be Element of S2 such that
A10:  F.n = [:A,B:];
     now let x be set;
       X-section([:A,B:],x) = B or X-section([:A,B:],x) = {} by Th16;
       hence X-section([:A,B:],x) in S2 by MEASURE1:7;
     end;
     hence F.n in K by AS,A10;
    end;
    hence C in K by A1,A7,A8,A9,Th41,FINSUB_1:def 1;
   end; then
   DisUnion measurable_rectangles(S1,S2) c= K;
   hence Field_generated_by measurable_rectangles(S1,S2) c= K by SRINGS_3:22;
   now let A be set;
    assume A in K; then
    ex A1 be Subset of [:X1,X2:] st
     A = A1 & for x be set holds X-section(A1,x) in S2 by AS;
    hence A in bool [:X1,X2:];
   end; then
   K c= bool [:X1,X2:]; then
   reconsider K as Subset-Family of [:X1,X2:];
   for C be Subset of [:X1,X2:] st C in K holds C` in K
   proof
    let C be Subset of [:X1,X2:];
    assume C in K; then
    consider C1 be Subset of [:X1,X2:] such that
A11: C = C1 & for x be set holds X-section(C1,x) in S2 by AS;
    now let x be set;
     per cases;
     suppose A12: x in X1;
A13:  X-section(C1,x) in S2 by A11;
      X2 in S2 by PROB_1:5; then
      X2 \ X-section(C1,x) in S2 by A13,PROB_1:6;
      hence X-section([:X1,X2:] \ C1,x) in S2 by A12,Th19;
     end;
     suppose not x in X1; then
      X-section([:X1,X2:] \ C1,x) = {} by Th17;
      hence X-section([:X1,X2:] \ C1,x) in S2 by MEASURE1:7;
     end;
    end; then
    [:X1,X2:] \ C in K by AS,A11;
    hence C` in K by SUBSET_1:def 4;
   end; then
   K is compl-closed by PROB_1:def 1; then
   reconsider K as Field_Subset of [:X1,X2:] by A7,A6;
   now let M be N_Sub_set_fam of [:X1,X2:];
    assume A15: M c= K;
    consider E be SetSequence of [:X1,X2:] such that
A16:  rng E = M by SUPINF_2:def 8;
    now let x be set;
     defpred P[Nat,object] means
       $2 = {y where y is Element of X2: [x,y] in E.$1};
A18: for n be Element of NAT ex d be Element of bool X2 st P[n,d]
     proof
      let n be Element of NAT;
      set d = {y where y is Element of X2: [x,y] in E.n};
      now let y be set;
       assume y in d; then
       ex y1 be Element of X2 st y = y1 & [x,y1] in E.n;
       hence y in X2;
      end; then
      d c= X2; then
      reconsider d as Element of bool X2;
      take d;
      thus P[n,d];
     end;
     consider D be Function of NAT,bool X2 such that
A19:  for n being Element of NAT holds P[n,D.n] from FUNCT_2:sch 3(A18);
     reconsider D as SetSequence of X2;
A20: for n be Nat holds D.n = X-section(E.n,x)
     proof
      let n be Nat;
      n is Element of NAT by ORDINAL1:def 12;
      hence thesis by A19;
     end;
A21: dom D = NAT by FUNCT_2:def 1;
     now let D0 be set;
      assume D0 in rng D; then
      consider n0 be Element of NAT such that
A22:   D0 = D.n0 by FUNCT_2:113;
A23:  D0 = X-section(E.n0,x) by A20,A22;
      E.n0 in K by A15,A16,FUNCT_2:112; then
      ex C0 be Subset of [:X1,X2:] st
       E.n0 = C0 & for x be set holds X-section(C0,x) in S2 by AS;
      hence D0 in S2 by A23;
     end; then
     rng D c= S2; then
     D is sequence of S2 by A21,FUNCT_2:2; then
A24: union rng D is Element of S2 by MEASURE1:24;
     X-section(union rng E,x) = union rng D by A20,Th24;
     hence X-section(union rng E,x) in S2 by A24;
    end;
    hence union M in K by AS,A16;
   end; then
   K is sigma-additive by MEASURE1:def 5;
   hence thesis;
end;
