
theorem
for f,g be sequence of ExtREAL st
 f is nonnegative &
 (ex N be Nat st (Ser f).N <= (Ser g).N
               & (for n be Nat st n > N holds f.n <= g.n))
 holds SUM f <= SUM g
proof
    let f,g be sequence of ExtREAL;
    assume that
A1:  f is nonnegative and
A2:  ex N be Nat st (Ser f).N <= (Ser g).N
               & (for n be Nat st n > N holds f.n <= g.n);
    consider N be Nat such that
A3:  (Ser f).N <= (Ser g).N and
A4:  for n be Nat st n > N holds f.n <= g.n by A2;

    defpred P[Nat] means (Ser f).(N+$1) <= (Ser g).(N+$1);
A5: P[0] by A3;
A6: for k be Nat st P[k] holds P[k+1]
    proof
     let k be Nat;
     assume A7: P[k];
A8:  (Ser f).(N+k+1) = (Ser f).(N+k) + f.(N+k+1)
   & (Ser g).(N+k+1) = (Ser g).(N+k) + g.(N+k+1) by SUPINF_2:def 11;
     N < N+k+1 by NAT_1:11,13; then
     f.(N+k+1) <= g.(N+k+1) by A4;
     hence P[k+1] by A7,A8,XXREAL_3:36;
    end;

A9: for m be Nat holds P[m] from NAT_1:sch 2(A5,A6);

    for x be ExtReal st x in rng Ser f
     ex y be ExtReal st y in rng Ser g & x <= y
    proof
     let x be ExtReal;
     assume x in rng Ser f; then
     consider n be Element of NAT such that
A10:  x = (Ser f).n by FUNCT_2:113;
     per cases;
     suppose n < N; then
      reconsider m = N-n as Nat by NAT_1:21;
      N = n + m; then
      (Ser f).n <= (Ser f).N by A1,SUPINF_2:41; then
A11:  x <= (Ser g).N by A3,A10,XXREAL_0:2;
      dom Ser g = NAT by FUNCT_2:def 1; then
      N in dom Ser g by ORDINAL1:def 12;
      hence thesis by A11,FUNCT_1:3;
     end;
     suppose n >= N; then
      reconsider m = n - N as Nat by NAT_1:21;
A12:  x <= (Ser g).(N+m) by A9,A10;
      dom Ser g = NAT by FUNCT_2:def 1;
      hence thesis by A12,FUNCT_1:3;
     end;
    end;
    hence SUM f <= SUM g by XXREAL_2:63;
end;
