reserve m, n for Nat;

theorem Th47:
  for p being Prime, n being non zero Nat holds (
  PFactors (p|^n)) * <* p *> = <* p *>
proof
  let p be Prime, n be non zero Nat;
  set s = p |^ n;
  set f = <*p*>, g = PFactors s;
A1: dom f = {1} by FINSEQ_1:2,38;
A2: dom (g * f) = {1}
  proof
    thus dom (g * f) c= {1}
    by A1,FUNCT_1:11;
    let x be object;
    assume
A3: x in {1};
    then x = 1 by TARSKI:def 1;
    then f.x = p;
    then f.x in SetPrimes by NEWTON:def 6;
    then
A4: f.x in dom g by PARTFUN1:def 2;
    x in dom f by A3,FINSEQ_1:2,38;
    hence thesis by A4,FUNCT_1:11;
  end;
A5: for x being object st x in dom (g * f) holds (g * f).x = f.x
  proof
    let x be object;
    (pfexp p).p <> 0 by NAT_3:38;
    then p in support pfexp p by PRE_POLY:def 7;
    then
A6: p in support pfexp s by NAT_3:48;
    assume
A7: x in dom (g * f);
    then
A8: x = 1 by A2,TARSKI:def 1;
    then (g * f).1 = g.(f.1) by A7,FUNCT_1:12
      .= g.p
      .= p by A6,Def6
      .= f.1;
    hence thesis by A8;
  end;
  dom (g * f) = dom f by A2,FINSEQ_1:2,38;
  hence thesis by A5,FUNCT_1:2;
end;
