reserve x for set;
reserve a, b, c, d, e for Real;
reserve m, n, m1, m2 for Nat;
reserve k, l for Integer;
reserve p for Rational;

theorem Th47:
  k is even implies (-a) to_power k = a to_power k
proof
  given l such that
A1: k=2*l;
  per cases;
    suppose a = 0;
     hence thesis;
    end;
    suppose a>0;
      hence a to_power k = (a to_power 2) to_power l by A1,Th33
        .= (a^2) to_power l by Th46
        .= ((-a)^2) to_power l
        .= ((-a) to_power 2) to_power l by Th46
        .= ((-a) #Z 2) to_power l by Def2
        .= ((-a) #Z 2) #Z l by Def2
        .= (-a) #Z (2*l) by PREPOWER:45
        .= (-a) to_power k by A1,Def2;
    end;
    suppose
   a<0;
then    -a>0 by XREAL_1:58;
      hence (-a) to_power k = ((-a) to_power 2) to_power l by A1,Th33
        .= ((-a)^2) to_power l by Th46
        .= (a^2) to_power l
        .= (a to_power 2) to_power l by Th46
        .= (a #Z 2) to_power l by Def2
        .= (a #Z 2) #Z l by Def2
        .= a #Z (2*l) by PREPOWER:45
        .= a to_power k by A1,Def2;
    end;
end;
