reserve a,b,c,d for positive Real,
  m,u,w,x,y,z for Real,
  n,k for Nat,
  s,s1 for Real_Sequence;

theorem
  (for n holds s.n=1/sqrt(n+1)) implies for n holds (Partial_Sums s).n<2
  *sqrt(n+1)
proof
  defpred X[Nat] means (Partial_Sums s).$1<2*sqrt($1+1);
  assume
A1: for n holds s.n=1/sqrt(n+1);
A2: for n st X[n] holds X[n+1]
  proof
    let n;
A3: sqrt(n+2)>0 by SQUARE_1:25;
    4*n^2+12*n+8<4*n^2+12*n+9 by XREAL_1:8;
    then sqrt(4*((n+2)*(n+1)))<sqrt(((2*n)+3)^2) by SQUARE_1:27;
    then 2*sqrt((n+2)*(n+1))<sqrt(((2*n)+3)^2) by SQUARE_1:20,29;
    then 2*sqrt((n+2)*(n+1))<2*n+3 by SQUARE_1:22;
    then 2*sqrt((n+2)*(n+1))+1<2*n+3+1 by XREAL_1:8;
    then 2*(sqrt(n+2)*sqrt(n+1))+1<2*(n+2) by SQUARE_1:29;
    then 2*(sqrt(n+2)*sqrt(n+1))+1<2*sqrt((n+2)^2) by SQUARE_1:22;
    then
    (2*(sqrt(n+2)*sqrt(n+1))+1)/sqrt(n+2)<(2*sqrt((n+2)*(n+2)))/sqrt(n+2)
    by A3,XREAL_1:74;
    then
    (2*(sqrt(n+2)*sqrt(n+1))+1)/sqrt(n+2)<(2*(sqrt(n+2)*sqrt(n+2)))/sqrt(
    n +2) by SQUARE_1:29;
    then
    (2*(sqrt(n+2)*sqrt(n+1))+1)/sqrt(n+2)<(2*sqrt(n+2))*sqrt(n+2)/sqrt(n+ 2 );
    then (2*(sqrt(n+2)*sqrt(n+1))+1)/sqrt(n+2)<2*sqrt(n+2) by A3,XCMPLX_1:89;
    then (2*sqrt(n+1))*sqrt(n+2)/sqrt(n+2)+1/sqrt(n+2)<2*sqrt(n+2) by
XCMPLX_1:62;
    then
A4: (2*sqrt(n+1))+1/sqrt(n+2)<2*sqrt(n+2) by A3,XCMPLX_1:89;
    assume (Partial_Sums s).n<2*sqrt(n+1);
    then (Partial_Sums s).n+1/sqrt(n+2)<2*sqrt(n+1)+1/sqrt(n+2) by XREAL_1:8;
    then (Partial_Sums s).n+1/sqrt((n+1)+1)<2*sqrt(n+2) by A4,XXREAL_0:2;
    then (Partial_Sums s).n+s.(n+1)<2*sqrt(n+2) by A1;
    hence thesis by SERIES_1:def 1;
  end;
  (Partial_Sums s).0 = s.0 by SERIES_1:def 1
    .=1/sqrt(0+1) by A1
    .=1;
  then
A5: X[0];
  for n holds X[n] from NAT_1:sch 2(A5,A2);
  hence thesis;
end;
