reserve i,j,k,l,m,n for Nat,
  D for non empty set,
  f for FinSequence of D;
reserve X for compact Subset of TOP-REAL 2;
reserve r for Real;
reserve f for non trivial FinSequence of TOP-REAL 2;
reserve f for non constant standard special_circular_sequence;

theorem Th47:
  1 <= i & i <= j & j < m & m <= n & n <= len f & (1 < i or n <
  len f) implies L~mid(f,i,j) misses L~mid(f,m,n)
proof
  assume that
A1: 1 <= i & i <= j and
A2: j < m and
A3: m <= n and
A4: n <= len f and
A5: 1 < i or n < len f;
  set A = { LSeg(f,k): i <= k & k < j}, B = { LSeg(f,l): m <= l & l < n};
  1 <= j by A1,XXREAL_0:2;
  then 1 < m by A2,XXREAL_0:2;
  then
A6: L~mid(f,m,n) = union B by A3,A4,Th14;
A7: for x,y being set st x in A & y in B holds x misses y
  proof
    let x,y be set;
    assume x in A;
    then consider k such that
A8: x = LSeg(f,k) and
A9: i <= k and
A10: k < j;
    assume y in B;
    then consider l such that
A11: y = LSeg(f,l) and
A12: m <= l and
A13: l < n;
A14: l < len f by A4,A13,XXREAL_0:2;
    l+1 <= n by A13,NAT_1:13;
    then
A15: k > 1 or l+1 < len f by A5,A9,XXREAL_0:2;
    k+1 <= j by A10,NAT_1:13;
    then k+1 < m by A2,XXREAL_0:2;
    then k+1 < l by A12,XXREAL_0:2;
    hence thesis by A8,A11,A14,A15,GOBOARD5:def 4;
  end;
  m <= len f by A3,A4,XXREAL_0:2;
  then j < len f by A2,XXREAL_0:2;
  then L~mid(f,i,j) = union A by A1,Th14;
  hence thesis by A6,A7,ZFMISC_1:126;
end;
