reserve A,A1,A2,B,B1,B2,C,O for Ordinal,
      R,S for Relation,
      a,b,c,o,l,r for object;
reserve x,y,z,t,r,l for Surreal,
        X,Y,Z for set;

theorem
  X is surreal-membered implies
   ex M be Ordinal st
     for o st o in X ex A be Ordinal st A in M & o in Day A
proof
  assume A1: X is surreal-membered;
  defpred P[object,object] means
  $1 is Surreal & for z be Surreal st z = $1 holds $2 = born z;
  A2: for x,y,z being object st P[x,y] & P[x,z] holds y = z
  proof
    let x,y,z be object such that A3: P[x,y] & P[x,z];
    reconsider x as Surreal by A3;
    thus y=born x by A3
    .=z by A3;
  end;
  consider OO be set such that
  A4: for z be object holds z in OO iff ex y be object st y in X & P[y,z]
  from TARSKI_0:sch 1(A2);
  for x be set st x in OO holds x is ordinal
  proof
    let x be set;
    assume x in OO;
    then consider y be object such that
    A5: y in X & P[y,x] by A4;
    reconsider y as Surreal by A5;
    x= born y by A5;
    hence thesis;
  end;
  then OO is ordinal-membered by ORDINAL6:1;
  then reconsider U=union OO as Ordinal;
  take succ U;
  let o be object such that A6: o in X;
  reconsider o as Surreal by A1,A6;
  P[o,born o];
  then born o c= U by A4,A6,ZFMISC_1:74;
  then A7: born o in succ U by ORDINAL1:6,12;
  o in Day born o by Def18;
  hence thesis by A7;
end;
