reserve T for non empty TopSpace,
  A, B for Subset of T,
  F, G for Subset-Family of T;

theorem Th47:
  for T being non empty TopSpace st T is T_1/2 holds T is T_0
proof
  let T be non empty TopSpace;
  assume
A1: T is T_1/2;
  now
    let x, y be Point of T;
    assume
A2: x <> y;
    assume that
A3: x in Cl {y} and
A4: y in Cl {x};
    not for G being Subset of T st G is open holds y in G implies {x} meets G
    proof
      set X = (Der {x})`;
      not x in Der {x}
      proof
        set U = the a_neighborhood of x;
        consider V being Subset of T such that
A5:     V is open and
        V c= U and
A6:     x in V by CONNSP_2:6;
        assume x in Der {x};
        then consider z being Point of T such that
A7:     z in {x} /\ V and
A8:     x <> z by A5,A6,TOPGEN_1:17;
        z in {x} by A7,XBOOLE_0:def 4;
        hence thesis by A8,TARSKI:def 1;
      end;
      then
A9:   x in (Der {x})` by SUBSET_1:29;
      assume
A10:  for G being Subset of T st G is open holds y in G implies {x} meets G;
      for U being open Subset of T st y in U ex r being Point of T st r in
      {x} /\ U & y <> r
      proof
        let U be open Subset of T;
        assume y in U;
        then {x} meets U by A10;
        then
A11:    x in U by ZFMISC_1:50;
        x in {x} by TARSKI:def 1;
        then x in {x} /\ U by A11,XBOOLE_0:def 4;
        hence thesis by A2;
      end;
      then y in Der {x} by TOPGEN_1:17;
      then
A12:  not y in X by XBOOLE_0:def 5;
      Der {x} is closed by A1;
      then {y} meets X by A3,A9,PRE_TOPC:24;
      hence thesis by A12,ZFMISC_1:50;
    end;
    hence contradiction by A4,PRE_TOPC:24;
  end;
  hence thesis by TSP_1:def 6;
end;
