
theorem :: Remark after 1.9. DEFINITION, p. 182
  for W being with_non-empty_element set
  holds W-INF(SC)_category = Intersect(W-INF_category, W-UPS_category)
proof
  let W be with_non-empty_element set;
  consider w being non empty set such that
A1: w in W by SETFAM_1:def 10;
  set r = the upper-bounded well-ordering Order of w;
A2: now
    let a be Object of W-INF_category, b be Object of W-UPS_category;
    idm a = id latt a by YELLOW21:2;
    hence a = b implies idm a = idm b by YELLOW21:2;
  end;
  set B = Intersect(W-INF_category, W-UPS_category);
A3: W-INF_category, W-UPS_category have_the_same_composition by YELLOW20:12;
  then
A4: the carrier of B = (the carrier of W-INF_category) /\
  (the carrier of W-UPS_category) by YELLOW20:def 3;
A5: RelStr(#w,r#) is Object of W-INF_category by A1,Th13;
  RelStr(#w,r#) is Object of W-UPS_category by A1,YELLOW21:14;
  then Intersect(W-INF_category, W-UPS_category) is non empty by A4,A5,
XBOOLE_0:def 4;
  then reconsider I = Intersect(W-INF_category, W-UPS_category) as
  non empty subcategory of W-INF_category by A2,YELLOW20:12,25;
  set A = W-INF(SC)_category;
  deffunc B(set,set) = (the Arrows of A).($1,$2);
A6: for C1, C2 being para-functional semi-functional category
  st the carrier of C1 = the carrier of A &
  (for a,b being Object of C1 holds <^a,b^> = B(a,b)) &
  the carrier of C2 = the carrier of A &
  (for a,b being Object of C2 holds <^a,b^> = B(a,b))
  holds the AltCatStr of C1 = the AltCatStr of C2 from YELLOW18:sch 19;
A7: the carrier of I = the carrier of A
  proof
    thus the carrier of I c= the carrier of A
    proof
      let x be object;
      assume x in the carrier of I;
      then reconsider x as Object of I;
      reconsider L = x as LATTICE by YELLOW21:def 4;
A8:   x in the carrier of W-UPS_category by A4,XBOOLE_0:def 4;
      then
A9:   L is strict complete by A1,YELLOW21:def 10;
      the carrier of L in W by A1,A8,YELLOW21:def 10;
      then L is Object of A by A9,Th43;
      hence thesis;
    end;
    let x be object;
    assume x in the carrier of A;
    then reconsider x as Object of A;
    reconsider L = x as LATTICE by YELLOW21:def 4;
A10: L is complete strict by Th43;
A11: the carrier of L in W by Th43;
    then
A12: x is Object of W-INF_category by A10,Th13;
    x is Object of W-UPS_category by A10,A11,YELLOW21:def 10;
    hence thesis by A4,A12,XBOOLE_0:def 4;
  end;
A13: for a,b being Object of A holds <^a,b^> = B(a,b) by ALTCAT_1:def 1;
  now
    let a,b be Object of I;
    reconsider a9 = a, b9 = b as Object of A by A7;
    reconsider a1 = a, b1 = b as Object of W-INF_category by A4,XBOOLE_0:def 4;
    reconsider a2 = a, b2 = b as Object of W-UPS_category by A4,XBOOLE_0:def 4;
A14: dom the Arrows of W-INF_category = [:the carrier of W-INF_category, the
    carrier of W-INF_category:] by PARTFUN1:def 2;
    dom the Arrows of W-UPS_category = [:the carrier of W-UPS_category, the
    carrier of W-UPS_category:] by PARTFUN1:def 2;
    then
A15: (dom the Arrows of W-INF_category) /\ (dom the Arrows of W
    -UPS_category) = [:(the carrier of W-INF_category)/\ the carrier of W
-UPS_category, (the carrier of W-INF_category)/\ the carrier of W-UPS_category
    :] by A14,ZFMISC_1:100;
A16: <^a,b^> = (the Arrows of I).(a,b) by ALTCAT_1:def 1
      .= Intersect(the Arrows of W-INF_category, the Arrows of W-UPS_category)
    . [a,b] by A3,YELLOW20:def 3
      .= ((the Arrows of W-INF_category).(a,b)) /\
    ((the Arrows of W-UPS_category). [a,b]) by A4,A15,YELLOW20:def 2
      .= <^a1,b1^> /\ ((the Arrows of W-UPS_category).(a,b)) by ALTCAT_1:def 1
      .= <^a1,b1^> /\ <^a2,b2^> by ALTCAT_1:def 1;
    now
      let f be object;
      f in <^a,b^> iff f in <^a1,b1^> & f in <^a2,b2^> by A16,XBOOLE_0:def 4;
      then f in <^a,b^> iff f is directed-sups-preserving Function of latt a2,
      latt b2 & f is infs-preserving Function of latt a1, latt b1
      by Th14,YELLOW21:15;
      then f in <^a,b^> iff f in <^a9,b9^> by Th44;
      hence f in <^a,b^> iff f in B(a,b) by ALTCAT_1:def 1;
    end;
    hence <^a,b^> = B(a,b) by TARSKI:2;
  end;
  hence thesis by A6,A7,A13;
end;
