reserve x,y for set,
  i for Nat;
reserve V for non empty CLSStruct,
  u,v,v1,v2,v3 for VECTOR of V,
  A for Subset of V,
  l, l1, l2 for C_Linear_Combination of A,
  x,y,y1,y2 for set,
  a,b for Complex,
  F for FinSequence of the carrier of V,
  f for Function of the carrier of V, COMPLEX;
reserve K,L,L1,L2,L3 for C_Linear_Combination of V;
reserve e,e1,e2 for Element of C_LinComb V;

theorem Th48:
  for V being non empty CLSStruct, M being Subset of V holds M is
  convex iff for z being Complex st (ex r being Real st z=r & 0 < r & r < 1)
  holds z*M + (1r-z)*M c= M
proof
  let V be non empty CLSStruct;
  let M be Subset of V;
A1: M is convex implies for z being Complex st (ex r being Real st z=r & 0 <
  r & r < 1) holds z*M + (1r-z)*M c= M
  proof
    assume
A2: M is convex;
    let z be Complex;
    assume
A3: ex r being Real st z=r & 0 < r & r < 1;
    for x being Element of V st x in z*M + (1r-z)*M holds x in M
    proof
      let x be Element of V;
      assume x in z*M + (1r-z)*M;
      then consider u,v be Element of V such that
A4:   x = u + v and
A5:   u in z*M & v in (1r-z)*M;
      ( ex w1 be Element of V st u = z * w1 & w1 in M)& ex w2 be Element
      of V st v = (1r-z)*w2 & w2 in M by A5;
      hence thesis by A2,A3,A4;
    end;
    hence thesis;
  end;
  ( for z being Complex st ( ex r being Real st z=r & 0 < r & r < 1 )
  holds z*M + (1r-z)*M c= M ) implies M is convex
  proof
    assume
A6: for z being Complex st (ex r being Real st z=r & 0 < r & r < 1)
    holds z*M + (1r-z)*M c= M;
    let u,v be VECTOR of V;
    let z be Complex;
    assume ex r being Real st z=r & 0 < r & r < 1;
    then
A7: z*M + (1r-z)*M c= M by A6;
    assume u in M & v in M;
    then z*u in z*M & (1r-z)*v in (1r-z)*M;
    then z*u + (1r-z)*v in z*M + (1r-z)*M;
    hence thesis by A7;
  end;
  hence thesis by A1;
end;
