
theorem Th48:
  for G1, G2 being _Graph, F being directed PGraphMapping of G1, G2
  for X,Y being Subset of the_Vertices_of G1 st F is weak_SG-embedding
  holds card G1.edgesDBetween(X,Y) c= card G2.edgesDBetween(F_V.:X,F_V.:Y)
proof
  let G1, G2 be _Graph, F be directed PGraphMapping of G1, G2;
  let X,Y be Subset of the_Vertices_of G1;
  assume A1: F is weak_SG-embedding;
  set f = F_E | G1.edgesDBetween(X,Y);
  A2: dom f = dom F_E /\ G1.edgesDBetween(X,Y) by RELAT_1:61
    .= the_Edges_of G1 /\ G1.edgesDBetween(X,Y) by A1, Def11
    .= G1.edgesDBetween(X,Y) by XBOOLE_1:28;
  for y being object holds y in rng f implies
    y in G2.edgesDBetween(F_V.:X,F_V.:Y)
  proof
    let y be object;
    assume y in rng f;
    then consider x being object such that
      A3: x in dom f & f.x = y by FUNCT_1:def 3;
    set v = (the_Source_of G1).x, w = (the_Target_of G1).x;
    A4: x DSJoins X,Y,G1 by A2, A3, GLIB_000:def 31;
    then A5: v in X & w in Y by GLIB_000:def 16;
    then v in the_Vertices_of G1 & w in the_Vertices_of G1;
    then A6: v in dom F_V & w in dom F_V by A1, Def11;
    A7: x in the_Edges_of G1 by A4, GLIB_000:def 16;
    then A8: x in dom F_E by A1, Def11;
    x DJoins v,w,G1 by A7, GLIB_000:def 14;
    then F_E.x DJoins F_V.v,F_V.w,G2 by A6, A8, Def14;
    then A9: y DJoins F_V.v,F_V.w,G2 by A3, FUNCT_1:47;
    F_V.v in F_V.:X & F_V.w in F_V.:Y by A5, A6, FUNCT_1:def 6;
    then y DSJoins F_V.:X,F_V.:Y,G2 by A9, GLIB_000:126;
    hence thesis by GLIB_000:def 31;
  end;
  then A10: rng f c= G2.edgesDBetween(F_V.:X,F_V.:Y) by TARSKI:def 3;
  f is one-to-one by A1, FUNCT_1:52;
  hence thesis by A2, A10, CARD_1:10;
end;
