reserve p,q for Point of TOP-REAL 2;

theorem Th48:
  for p1,p2 being Point of TOP-REAL 2, P being compact non empty
Subset of TOP-REAL 2 st P={p where p is Point of TOP-REAL 2: |.p.|=1} & LE p1,
  p2,P & p1<>p2 & p1`2<=0 & p1<>W-min(P) holds p1`1>p2`1
proof
  let p1,p2 be Point of TOP-REAL 2, P be compact non empty Subset of TOP-REAL
  2;
  assume that
A1: P={p where p is Point of TOP-REAL 2: |.p.|=1} and
A2: LE p1,p2,P and
A3: p1<>p2 and
A4: p1`2<=0 and
A5: p1<>W-min(P);
A6: P is being_simple_closed_curve by A1,JGRAPH_3:26;
  then
A7: p2 in P by A2,JORDAN7:5;
  set P4=Lower_Arc(P);
A8: Lower_Arc(P)={p where p is Point of TOP-REAL 2:p in P & p`2<=0} by A1,Th35;
A9: Upper_Arc(P) /\ P4={W-min(P),E-max(P)} by A6,JORDAN6:def 9;
A10: p1 in P by A2,A6,JORDAN7:5;
  now
    assume
A11: p1 in Upper_Arc(P);
    p1 in Lower_Arc(P) by A4,A10,A8;
    then p1 in {W-min(P),E-max(P)} by A9,A11,XBOOLE_0:def 4;
    then p1=W-min(P) or p1=E-max(P) by TARSKI:def 2;
    then
A12: p1= |[1,0]| by A1,A5,Th30;
    then
A13: p1`1=1 by EUCLID:52;
A14: ex p9 being Point of TOP-REAL 2 st p9=p2 & |.p9.|=1 by A1,A7;
A15: now
      assume
A16:  p2`1=1;
      1^2 =(p2`1)^2+(p2`2)^2 by A14,JGRAPH_3:1;
      then p2`2=0 by A16,XCMPLX_1:6;
      hence contradiction by A3,A12,A16,EUCLID:53;
    end;
    p2`1<=1 by A14,Th1;
    hence thesis by A13,A15,XXREAL_0:1;
  end;
  then
A17: p1 in Lower_Arc(P) & p2 in Lower_Arc(P)& not p2=W-min(P) & LE p1,p2,
  Lower_Arc(P),E-max(P),W-min(P) or p1`1>p2`1 by A2;
  consider f being Function of I[01],(TOP-REAL 2)|Lower_Arc(P) such that
A18: f is being_homeomorphism and
A19: for q1,q2 being Point of TOP-REAL 2, r1,r2 being Real st f.r1=q1 &
  f.r2=q2 & r1 in [.0,1.] & r2 in [.0,1.] holds r1<r2 iff q1`1>q2`1 and
A20: f.0=E-max(P) & f.1=W-min(P) by A1,Th42;
A21: rng f=[#]((TOP-REAL 2)|Lower_Arc(P)) by A18,TOPS_2:def 5
    .=Lower_Arc(P) by PRE_TOPC:def 5;
  now
    per cases;
    case
A22:  not p1`1 > p2`1;
      then consider x1 being object such that
A23:  x1 in dom f and
A24:  p1=f.x1 by A17,A21,FUNCT_1:def 3;
      consider x2 being object such that
A25:  x2 in dom f and
A26:  p2=f.x2 by A17,A21,A22,FUNCT_1:def 3;
A27:  dom f=[#](I[01]) by A18,TOPS_2:def 5
        .=[.0,1.] by BORSUK_1:40;
      reconsider r22=x2 as Real by A25;
A28:  0<=r22 & r22<=1 by A25,A27,XXREAL_1:1;
      reconsider r11=x1 as Real by A23;
A29:  r11<r22 iff p1`1>p2`1 by A19,A23,A24,A25,A26,A27;
      r11<=1 by A23,A27,XXREAL_1:1;
      then r11<=r22 or p1`1>p2`1 by A17,A18,A20,A24,A26,A28,JORDAN5C:def 3;
      hence thesis by A3,A24,A26,A29,XXREAL_0:1;
    end;
    case
      p1`1>p2`1;
      hence thesis;
    end;
  end;
  hence thesis;
end;
