reserve m,n,i,i2,j for Nat,
  r,r1,r2,s,t for Real,
  x,y,z for object;
reserve p,p1,p2,p3,q,q1,q2,q3,q4 for Point of TOP-REAL n;
reserve u for Point of Euclid n;

theorem Th35:
  for a being Real, Q being Subset of TOP-REAL n, w1,w7 being
Point of TOP-REAL n st n>=2 & Q={q : (|.q.|) > a } & w1 in Q & w7 in Q &
  (ex r being Real
    st w1=r*w7 or w7=r*w1) holds ex w2,w3,w4,w5,w6 being Point of
TOP-REAL n st w2 in Q & w3 in Q & w4 in Q & w5 in Q & w6 in Q & LSeg(w1,w2) c=Q
  & LSeg(w2,w3) c= Q & LSeg(w3,w4) c= Q & LSeg(w4,w5) c= Q & LSeg(w5,w6) c=Q &
  LSeg(w6,w7) c= Q
proof
  let a be Real, Q be Subset of TOP-REAL n,
      w1,w7 be Point of TOP-REAL n;
  assume
A1: n>=2 & Q={q : (|.q.|) > a } & w1 in Q & w7 in Q;
  reconsider y1=w1 as Element of REAL n by EUCLID:22;
  given r8 being Real such that
A2: w1=r8*w7 or w7=r8*w1;
  per cases;
  suppose
A3: a>=0;
    now
      assume
A4:   w1=0.TOP-REAL n;
      ex q st q=w1 & (|.q.|)>a by A1;
      hence contradiction by A3,A4,TOPRNS_1:23;
    end;
    then w1 <> 0*n by EUCLID:70;
    then consider y being Element of REAL n such that
A5: not ex r being Real st y=r*y1 or y1=r*y by A1,Th34;
    set y4=((a+1)/|.y.|)*y;
    reconsider w4=y4 as Point of TOP-REAL n by EUCLID:22;
A6: now
A7:   0 *y1 = 0 * w1
        .= 0.TOP-REAL n by RLVECT_1:10
        .=0*n by EUCLID:70;
      assume |.y.|=0;
      hence contradiction by A5,A7,EUCLID:8;
    end;
    then
A8: (a+1)/|.y.|>0 by A3,XREAL_1:139;
A9: now
      reconsider y9=y,y19=y1 as Element of n-tuples_on REAL;
      given r being Real such that
A10:  w1=r*w4 or w4=r*w1;
      per cases by A10;
      suppose
        w1=r*w4;
        then y1=(r*((a+1)/|.y.|))*y by RVSUM_1:49;
        hence contradiction by A5;
      end;
      suppose
        w4=r*w1;
        then ((a+1)/|.y.|)"*((a+1)/|.y.|)*y9=((a+1)/|.y.|)"*(r*y1) by
RVSUM_1:49;
        then ((a+1)/|.y.|)"*((a+1)/|.y.|)*y=((a+1)/|.y.|)"*r*y19 by RVSUM_1:49;
        then 1 *y=((a+1)/|.y.|)"*r*y1 by A8,XCMPLX_0:def 7;
        then y=((a+1)/|.y.|)"*r*y1 by RVSUM_1:52;
        hence contradiction by A5;
      end;
    end;
A11: |.w4.|=|.(a+1)/|.y.|.|*|.y.| by EUCLID:11
      .= (a+1)/|.y.|*|.y.| by A3,ABSVALUE:def 1
      .=a+1 by A6,XCMPLX_1:87;
    then |.w4.|>a by XREAL_1:29;
    then
A12: w4 in Q by A1;
    now
      given r1 being Real such that
A13:  w4=r1*w7 or w7=r1*w4;
A14:  now
        assume r1=0;
        then
A15:    w4=0.TOP-REAL n or w7=0.TOP-REAL n by A13,RLVECT_1:10;
        ex q7 being Point of TOP-REAL n st q7=w7 & |.q7.|>a by A1;
        hence contradiction by A3,A11,A15,TOPRNS_1:23;
      end;
      per cases by A2;
      suppose
A16:    w1=r8*w7;
        now
          per cases by A13;
          case
            w4=r1*w7;
            then r1"*w4=r1"*r1*w7 by RLVECT_1:def 7;
            then r1"*w4=1 *w7 by A14,XCMPLX_0:def 7;
            then r1"*w4=w7 by RLVECT_1:def 8;
            then w1=r8*r1"*w4 by A16,RLVECT_1:def 7;
            hence contradiction by A9;
          end;
          case
            w7=r1*w4;
            then r1"*w7=r1"*r1*w4 by RLVECT_1:def 7;
            then r1"*w7=1 *w4 by A14,XCMPLX_0:def 7;
            then r1"*w7=w4 by RLVECT_1:def 8;
            then r1""*w4=r1""*r1"*w7 by RLVECT_1:def 7;
            then r1""*w4=1 *w7 by A14,XCMPLX_0:def 7;
            then r1""*w4=w7 by RLVECT_1:def 8;
            then w1=r8*r1""*w4 by A16,RLVECT_1:def 7;
            hence contradiction by A9;
          end;
        end;
        hence contradiction;
      end;
      suppose
A17:    w7=r8*w1;
A18:    now
          assume r8=0;
          then
A19:      w7=0.TOP-REAL n by A17,RLVECT_1:10;
          ex q7 being Point of TOP-REAL n st q7=w7 & |.q7.|>a by A1;
          hence contradiction by A3,A19,TOPRNS_1:23;
        end;
        r8"*w7=r8"*r8*w1 by A17,RLVECT_1:def 7;
        then r8"*w7=1 *w1 by A18,XCMPLX_0:def 7;
        then
A20:    r8"*w7=w1 by RLVECT_1:def 8;
        now
          per cases by A13;
          case
            w4=r1*w7;
            then r1"*w4=r1"*r1*w7 by RLVECT_1:def 7;
            then r1"*w4=1 *w7 by A14,XCMPLX_0:def 7;
            then r1"*w4=w7 by RLVECT_1:def 8;
            then w1=r8"*r1"*w4 by A20,RLVECT_1:def 7;
            hence contradiction by A9;
          end;
          case
            w7=r1*w4;
            then r1"*w7=r1"*r1*w4 by RLVECT_1:def 7;
            then r1"*w7=1 *w4 by A14,XCMPLX_0:def 7;
            then r1"*w7=w4 by RLVECT_1:def 8;
            then r1""*w4=r1""*r1"*w7 by RLVECT_1:def 7;
            then r1""*w4=1 *w7 by A14,XCMPLX_0:def 7;
            then r1""*w4=w7 by RLVECT_1:def 8;
            then w1=r8"*r1""*w4 by A20,RLVECT_1:def 7;
            hence contradiction by A9;
          end;
        end;
        hence contradiction;
      end;
    end;
    then
A21: ex w29,w39 being Point of TOP-REAL n st w29 in Q & w39 in Q & LSeg(w4,
    w29) c=Q & LSeg(w29,w39) c= Q & LSeg(w39,w7) c= Q by A1,A12,Th29;
    ex w2,w3 being Point of TOP-REAL n st w2 in Q & w3 in Q & LSeg(w1,w2)
    c=Q & LSeg(w2,w3) c= Q & LSeg(w3,w4) c= Q by A1,A12,A9,Th29;
    hence thesis by A12,A21;
  end;
  suppose
A22: a<0;
    set w2=0.TOP-REAL n;
A23: REAL n c= Q
    proof
      let x be object;
      assume x in REAL n;
      then reconsider w=x as Point of TOP-REAL n by EUCLID:22;
      |.w.|>=0;
      hence thesis by A1,A22;
    end;
    the carrier of TOP-REAL n=REAL n by EUCLID:22;
    then
A24: Q=the carrier of TOP-REAL n by A23;
    then LSeg(w1,w2) c=Q & LSeg(w2,w7) c=Q;
    hence thesis by A24;
  end;
end;
