reserve A for set,
  C for non empty set,
  B for Subset of A,
  x for Element of A,
  f,g for Function of A,C;
reserve B for Element of Fin A;
reserve L for non empty LattStr,
  a,b,c for Element of L;
reserve L for Lattice;
reserve a,b,c,u,v for Element of L;
reserve A for non empty set,
  x for Element of A,
  B for Element of Fin A,
  f,g for Function of A, the carrier of L;

theorem
  for L being Lattice holds L is lower-bounded iff L.: is upper-bounded
proof
  let L be Lattice;
  thus L is lower-bounded implies L.: is upper-bounded
  proof
    given c being Element of L such that
A1: for a being Element of L holds c"/\"a = c & a"/\"c = c;
    reconsider c9 = c as Element of L.:;
    take c9;
    let a9 be Element of L.:;
    reconsider a = a9 as Element of L;
    thus c9"\/"a9 = c"/\"a .= c9 by A1;
    hence a9"\/"c9 = c9;
  end;
  given c being Element of L.: such that
A2: for a being Element of L.: holds c"\/"a = c & a"\/"c = c;
  reconsider c9= c as Element of L;
  take c9;
  let a9 be Element of L;
  reconsider a = a9 as Element of L.:;
  thus c9"/\"a9 = c"\/"a .= c9 by A2;
  hence a9"/\"c9 = c9;
end;
