reserve i,j,n,k for Nat,
  a for Element of COMPLEX,
  R1,R2 for Element of i-tuples_on COMPLEX;

theorem Th46:
  for f,g being FinSequence of COMPLEX,n being Nat st len f = n +
  1 & g = f|n holds Sum f = Sum g + f/.(len f)
proof
  let f,g be FinSequence of COMPLEX,n be Nat;
  assume that
A1: len f = n + 1 and
A2: g = f|n;
A3: dom f = Seg(n+1) by A1,FINSEQ_1:def 3;
  set q = <*f/.len f*>;
  set p = g^q;
A4: len q = 1 by FINSEQ_1:39;
  set n9=Seg n;
A5: g=f|n9 by A2,FINSEQ_1:def 16;
A6: n <= len f by A1,NAT_1:11;
A7: now
    let u be object;
    assume
A8: u in dom f;
    then u in { k where k is Nat : 1 <= k & k <= n+1 } by A3,FINSEQ_1:def 1;
    then consider i being Nat such that
A9: u = i and
A10: 1 <= i and
A11: i <= n+1;
    now
      per cases;
      case
A12:    i = n+1;
        then
A13:    len g + 1 <= i by A1,A2,FINSEQ_1:59,NAT_1:11;
        i <= len g + len q by A1,A2,A4,A12,FINSEQ_1:59,NAT_1:11;
        hence p.i = q.(i-len g) by A13,FINSEQ_1:23
          .= q.(n+1-n) by A1,A2,A12,FINSEQ_1:59,NAT_1:11
          .= f/.(n+1) by A1,FINSEQ_1:40
          .= f.i by A8,A9,A12,PARTFUN1:def 6;
      end;
      case
        i <> n+1;
        then i < n+1 by A11,XXREAL_0:1;
        then i <= n by NAT_1:13;
        then i in { k where k is Nat : 1 <= k & k <= n } by A10;
        then i in Seg n by FINSEQ_1:def 1;
        then
A14:    i in dom g by A5,A6,FINSEQ_1:17;
        then p.i = g.i by FINSEQ_1:def 7;
        hence p.i = f.i by A5,A14,FUNCT_1:47;
      end;
    end;
    hence f.u = p.u by A9;
  end;
  len(g^q) = len g + len q by FINSEQ_1:22
    .= len g + 1 by FINSEQ_1:40
    .= len f by A1,A2,FINSEQ_1:59,NAT_1:11;
  then dom f = Seg len(g^q) by FINSEQ_1:def 3
    .= dom(g^q) by FINSEQ_1:def 3;
  then f = g^<*(f/.(len f))*> by A7,FUNCT_1:2;
  hence Sum f = Sum g + Sum <*(f/.len f)*> by Th44
    .= Sum g + (f/.len f) by FINSOP_1:11;
end;
