reserve E, F, G,S,T,W,Y for RealNormSpace;
reserve f,f1,f2 for PartFunc of S,T;
reserve Z for Subset of S;
reserve i,n for Nat;

theorem Th49:
  for E,F be RealNormSpace,
      Z be non empty Subset of E,
      L1 be PartFunc of E,F,
      L0 be Point of F
   st Z is open & L1 = Z --> L0
  holds
    for i be Nat
    holds
    ( ex P be Point of diff_SP(i,E,F)
      st diff(L1,i,Z) = Z --> P )
    & diff (L1,i,Z) is_differentiable_on Z
    & diff (L1,i,Z)`|Z is_continuous_on Z
proof
  let E,F be RealNormSpace,
      Z be non empty Subset of E,
      L1 be PartFunc of E,F,
      L0 be Point of F;
  assume A1: Z is open & L1 = Z --> L0;

  defpred P[Nat] means
  ( ex P be Point of diff_SP($1,E,F)
    st diff(L1,$1,Z) = Z --> P )
  & diff(L1,$1,Z) is_differentiable_on Z
  & diff(L1,$1,Z) `| Z is_continuous_on Z;

  A2: P[0]
  proof
    A3: diff_SP(0,E,F) = F by NDIFF_6:7;

    A4: diff(L1,0,Z)
     = L1|Z by NDIFF_6:11
    .= L1 by A1;

    thus ex P be Point of diff_SP(0,E,F) st diff(L1,0,Z) = Z --> P by A1,A3,A4;
    thus diff(L1,0,Z) is_differentiable_on Z by A1,A3,A4,Th48;
    thus diff(L1,0,Z) `| Z is_continuous_on Z by A1,A3,A4,Th48;
  end;

  A5: for i be Nat st P[i] holds P[i+1]
  proof
    let i be Nat;
    assume P[i];
    then consider P be Point of diff_SP(i,E,F) such that
    A6: diff(L1,i,Z) = Z --> P;

    A7: diff_SP(i+1,E,F)
      = R_NormSpace_of_BoundedLinearOperators(E, diff_SP(i,E,F))
        by NDIFF_6:10;

    A8: diff(L1,i+1,Z)
     = diff(L1,i,Z) `| Z by NDIFF_6:13
    .= Z --> 0.diff_SP(i+1,E,F) by A1,A6,A7,Th48;
    hence ex P be Point of diff_SP(i+1,E,F) st diff(L1,i+1,Z) = Z --> P;
    thus diff(L1,i+1,Z) is_differentiable_on Z by A1,A8,Th48;
    thus diff(L1,i+1,Z) `| Z is_continuous_on Z by A1,A8,Th48;
  end;

  for i be Nat holds P[i] from NAT_1:sch 2(A2,A5);
  hence thesis;
end;
