reserve p,q,r,s,A,B for Element of PL-WFF,
  F,G,H for Subset of PL-WFF,
  k,n for Element of NAT,
  f,f1,f2 for FinSequence of PL-WFF;
reserve M for PLModel;

theorem Th36:
  for A be Element of PL_axioms holds
    (A is axpl1 or A is axpl2 or A is axpl3)
 proof
  defpred P1[Element of PL_axioms] means
  $1 is axpl1 or $1 is axpl2 or $1 is axpl3;
  set X={p where p is Element of PL_axioms:P1[p]};
  X c=PL-WFF
  proof
   let x be object;
   assume x in X;
   then ex p be Element of PL_axioms st x=p & P1[p];
   hence x in PL-WFF;
  end;
  then reconsider X as Subset of PL-WFF;
  let A be Element of PL_axioms;
  X is with_PL_axioms
  proof
   let p,q,r;
   thus p => (q => p) in X
   proof
    reconsider pp=p =>(q =>p) as Element of PL_axioms by withplax;
    P1[pp] by defaxpl1;
    hence thesis;
   end;
   thus (p => (q => r)) => ((p=>q)=>(p=>r)) in X
   proof
    reconsider pp=(p => (q => r)) => ((p=>q)=>(p=>r))
    as Element of PL_axioms by withplax;
    P1[pp] by defaxpl2;
    hence thesis;
   end;
   thus ('not' q => 'not' p) => (('not' q => p)=>q) in X
   proof
    reconsider pp=('not' q => 'not' p) => (('not' q => p)=>q)
    as Element of PL_axioms by withplax;
    P1[pp] by defaxpl3;
    hence thesis;
   end;
  end;
  then A in PL_axioms & PL_axioms c=X by defplax;
  then A in X;
  then ex p be Element of PL_axioms st A=p & P1[p];
  hence P1[A];
 end;
