reserve x for set;
reserve a, b, c, d, e for Real;
reserve m, n, m1, m2 for Nat;
reserve k, l for Integer;
reserve p for Rational;

theorem
  k is odd implies (-a) to_power k = -(a to_power k)
proof
  assume
A1:  k is odd;
  then consider l such that
A2: k=2*l + 1 by ABIAN:1;
  per cases;
    suppose
A3:    a = 0;
   k <> 0 by A1;
      then a to_power k = 0 by A3,Th42;
     hence thesis by A3;
    end;
    suppose
A4:   a>0;
then A5:   -a<>-0;
   a to_power k = a to_power (2*l) * a to_power 1 by A2,A4,Th27
        .= a to_power (2*l) * a
        .= (-a) to_power (2*l) * a by Th47
        .= - (-a) to_power (2*l) * (-a)
        .= - (-a) #Z (2*l) * (-a) by Def2
        .= - (-a) #Z (2*l) * (-a) #Z 1 by PREPOWER:35
        .= - (-a) #Z k by A2,A5,PREPOWER:44
        .= - (-a) to_power k by Def2;
      hence thesis;
    end;
    suppose
A6:   a<0;
then    -a>0 by XREAL_1:58;
      hence
(-a) to_power k = (-a) to_power (2*l) * (-a) to_power 1 by A2,Th27
        .= (-a) to_power (2*l) * (-a)
        .= a to_power (2*l) * (-a) by Th47
        .= - a to_power (2*l) * a
        .= - a #Z (2*l) * a by Def2
        .= - a #Z (2*l) * a #Z 1 by PREPOWER:35
        .= - a #Z k by A2,A6,PREPOWER:44
        .= - a to_power k by Def2;
    end;
end;
