reserve R for non empty RelStr,
  N for net of R,
  i for Element of N;

theorem  :: 1.10. Propostion (iv), p.104
  for T being complete continuous Scott TopLattice, S being Subset of T
  holds Int S = union{wayabove x where x is Element of T: wayabove x c= S}
proof
  let T be complete continuous Scott TopLattice, S be Subset of T;
  set B = the set of all  wayabove x where x is Element of T;
  set I = { G where G is Subset of T: G in B & G c= S },
  P = {wayabove x where x is Element of T: wayabove x c= S};
A1: I = P
  proof
    thus I c= P
    proof
      let e be object;
      assume e in I;
      then consider G being Subset of T such that
A2:   e = G and
A3:   G in B and
A4:   G c= S;
      ex x being Element of T st G = wayabove x by A3;
      hence thesis by A2,A4;
    end;
    let e be object;
    assume e in P;
    then consider x being Element of T such that
A5: e = wayabove x and
A6: wayabove x c= S;
    wayabove x in B;
    hence thesis by A5,A6;
  end;
  B is Basis of T by Th45;
  hence thesis by A1,YELLOW_8:11;
end;
