
theorem Th48:
  for W being with_non-empty_element set
  for L being LATTICE st the carrier of L in W
  holds L is Object of W-CL_category iff L is strict complete continuous
proof
  let W be with_non-empty_element set;
A1: ex a being non empty set st a in W by SETFAM_1:def 10;
A2: the carrier of W-INF(SC)_category c= the carrier of W-INF_category
  by ALTCAT_2:def 11;
A3: the carrier of W-CL_category c= the carrier of W-INF(SC)_category
  by ALTCAT_2:def 11;
  let L be LATTICE;
  assume
A4: the carrier of L in W;
  hereby
    assume
A5: L is Object of W-CL_category;
    then L in the carrier of W-CL_category;
    then reconsider a = L as Object of W-INF(SC)_category by A3;
A6: a in the carrier of W-INF(SC)_category;
    latt a is continuous by A5,Def12;
    hence L is strict complete continuous by A1,A2,A6,Def4;
  end;
  assume
A7: L is strict complete continuous;
  then L is Object of W-INF_category by A4,Def4;
  then reconsider a = L as Object of W-INF(SC)_category by Def10;
  latt a = L;
  hence thesis by A7,Def12;
end;
