
theorem Th49:
  for C1, C2 being Coherence_Space for f being U-stable Function
  of C1,C2 holds f is U-linear iff
  for a being set, y being object st [a,y] in Trace f ex x
  being set st a = {x}
proof
  let C1, C2 be Coherence_Space;
  let f be U-stable Function of C1,C2;
A1: dom f = C1 by FUNCT_2:def 1;
  hereby
    assume
A2: f is U-linear;
    let a be set,y be object;
    assume
A3: [a,y] in Trace f;
    then
A4: a in dom f by Th31;
    y in f.a by A3,Th31;
    then consider x being set such that
A5: x in a and
A6: y in f.{x} and
    for b being set st b c= a & y in f.b holds x in b by A1,A2,A4,Th23;
A7: {x} c= a by A5,ZFMISC_1:31;
    take x;
A8: {x,x} = {x} by ENUMSET1:29;
    {x,x} in C1 by A1,A4,A5,COH_SP:6;
    hence a = {x} by A1,A3,A6,A7,A8,Th31;
  end;
  assume
A9: for a being set,y being object
  st [a,y] in Trace f ex x being set st a = {x};
  now
    let a, y be set;
    assume that
A10: a in dom f and
A11: y in f.a;
    consider b being set such that
    b is finite and
A12: b c= a and
A13: y in f.b and
A14: for c being set st c c= a & y in f.c holds b c= c by A1,A10,A11,Th22;
    now
      thus b in dom f by A1,A10,A12,CLASSES1:def 1;
      let c be set;
      assume that
      c in dom f and
A15:  c c= b and
A16:  y in f.c;
      c c= a by A12,A15;
      then b c= c by A14,A16;
      hence b = c by A15;
    end;
    then [b,y] in Trace f by A13,Th31;
    then consider x being set such that
A17: b = {x} by A9;
    take x;
    x in b by A17,TARSKI:def 1;
    hence x in a & y in f.{x} by A12,A13,A17;
    let c be set;
    assume c c= a & y in f.c;
    then b c= c by A14;
    hence x in c by A17,ZFMISC_1:31;
  end;
  hence thesis by A1,Th23;
end;
