reserve x,y for set,
  i for Nat;
reserve V for non empty CLSStruct,
  u,v,v1,v2,v3 for VECTOR of V,
  A for Subset of V,
  l, l1, l2 for C_Linear_Combination of A,
  x,y,y1,y2 for set,
  a,b for Complex,
  F for FinSequence of the carrier of V,
  f for Function of the carrier of V, COMPLEX;
reserve K,L,L1,L2,L3 for C_Linear_Combination of V;
reserve e,e1,e2 for Element of C_LinComb V;

theorem
  for V being Abelian non empty CLSStruct, M being Subset of V st M is
  convex holds for z being Complex st (ex r being Real st z=r & 0 < r & r < 1)
  holds (1r-z)*M + z*M c= M
proof
  let V be Abelian non empty CLSStruct;
  let M be Subset of V;
  assume
A1: M is convex;
  let z be Complex;
  assume
A2: ex r being Real st z=r & 0 < r & r < 1;
  for x being Element of V st x in (1r-z)*M + z*M holds x in M
  proof
    let x be Element of V;
    assume x in (1r-z)*M + z*M;
    then consider u,v be Element of V such that
A3: x = u + v and
A4: u in (1r-z)*M & v in z*M;
    ( ex w1 be Element of V st u = (1r-z) * w1 & w1 in M)& ex w2 be
    Element of V st v = z*w2 & w2 in M by A4;
    hence thesis by A1,A2,A3;
  end;
  hence thesis;
end;
