reserve D for non empty set,
  i,j,k,l for Nat,
  n for Nat,
  x for set,
  a,b,c,r,r1,r2 for Real,
  p,q for FinSequence of REAL,
  MR,MR1 for Matrix of REAL;

theorem
  for p being nonnegative FinSequence of REAL for q holds q = -
  Infor_FinSeq_of p iff (len q = len p & for k st k in dom q holds q.k = p.k *
  log(2,1/(p.k)))
proof
  let p be nonnegative FinSequence of REAL, q;
  set p0 = Infor_FinSeq_of p;
  hereby
    assume
A1: q = -p0;
    then
A2: dom q = dom p0 by VALUED_1:8;
A3: Seg len q = dom q by FINSEQ_1:def 3
      .= Seg len p0 by A2,FINSEQ_1:def 3
      .= Seg len p by Th47;
    for k st k in dom q holds q.k = p.k * log(2,1/(p.k))
    proof
      let k such that
A4:   k in dom q;
      k in Seg len q by A4,FINSEQ_1:def 3;
      then
A5:   k in dom p by A3,FINSEQ_1:def 3;
A6:   q.k = -p0.k by A1,RVSUM_1:17;
      then
A7:   q.k = -(p.k * log(2,p.k)) by A2,A4,Th47
        .= p.k * (-log(2,p.k));
      per cases by A5,Def1;
      suppose
A8:     p.k=0;
        then p0.k=0 by A5,Th48;
        hence thesis by A6,A8;
      end;
      suppose
        p.k>0;
        hence thesis by A7,Th5;
      end;
    end;
    hence len q = len p & for k st k in dom q holds q.k = p.k * log(2,1/(p.k))
    by A3,FINSEQ_1:6;
  end;
  assume that
A9: len q = len p and
A10: for k st k in dom q holds q.k = p.k * log(2,1/(p.k));
A11: dom q = Seg len q by FINSEQ_1:def 3
    .= Seg len p0 by A9,Th47
    .= dom p0 by FINSEQ_1:def 3;
A12: for k be Nat st k in dom q holds (-p0).k = q.k
  proof
    let k be Nat;
    assume
A13: k in dom q;
    then k in Seg len p by A9,FINSEQ_1:def 3;
    then
A14: k in dom p by FINSEQ_1:def 3;
    per cases by A14,Def1;
    suppose
A15:  p.k = 0;
      thus (-p0).k = -p0.k by RVSUM_1:17
        .= -0 by A14,A15,Th48
        .= p.k * log(2,1/(p.k)) by A15
        .= q.k by A10,A13;
    end;
    suppose
A16:  p.k > 0;
      thus (-p0).k = -p0.k by RVSUM_1:17
        .= -(p.k * log(2,p.k)) by A11,A13,Th47
        .= p.k * (-log(2,p.k))
        .= p.k * log(2,1/(p.k)) by A16,Th5
        .= q.k by A10,A13;
    end;
  end;
  dom q = dom -p0 by A11,VALUED_1:8;
  hence thesis by A12,FINSEQ_1:13;
end;
